Spanish query

src/scribe_data/language_data_extraction/Spanish/adjectives/query_adjectives.sparql

@@ -0,0 +1,49 @@
+# tool: scribe-data
+# All Spanish (Q1321) adjectives.
+# Enter this query at https://query.wikidata.org/.
+
+SELECT
+  (REPLACE(STR(?lexeme), "http://www.wikidata.org/entity/", "") AS ?lexemeID)
+  ?adjective
+  ?masSingular
+  ?masPlural
+  ?femSingular
+  ?femPlural
+
+WHERE {
+  ?lexeme dct:language wd:Q1321 ;
+    wikibase:lexicalCategory wd:Q34698 ;
+    wikibase:lemma ?adjective .
+
+  # MARK: Masculine Singular
+  OPTIONAL {
+    ?lexeme ontolex:lexicalForm ?masSingularForm .
+    ?masSingularForm ontolex:representation ?masSingular ;
+      wikibase:grammaticalFeature wd:Q499327 ;
+      wikibase:grammaticalFeature wd:Q110786 .
+  }
+
+  # MARK: Masculine Plural
+  OPTIONAL {
+    ?lexeme ontolex:lexicalForm ?masPluralForm .
+    ?masPluralForm ontolex:representation ?masPlural ;
+      wikibase:grammaticalFeature wd:Q499327 ;
+      wikibase:grammaticalFeature wd:Q146786 .
+  }
+
+  # MARK: Feminine Singular
+  OPTIONAL {
+    ?lexeme ontolex:lexicalForm ?femSingularForm .
+    ?femSingularForm ontolex:representation ?femSingular ;
+      wikibase:grammaticalFeature wd:Q1775415 ;
+      wikibase:grammaticalFeature wd:Q110786 .
+  }
+
+  # MARK: Feminine Plural
+  OPTIONAL {
+    ?lexeme ontolex:lexicalForm ?femPluralForm .
+    ?femPluralForm ontolex:representation ?femPlural ;
+      wikibase:grammaticalFeature wd:Q1775415 ;
+      wikibase:grammaticalFeature wd:Q146786 .
+  }
+}

src/scribe_data/language_data_extraction/Spanish/adverbs/query_adverbs.sparql

@@ -0,0 +1,29 @@
+# tool: scribe-data
+# All Spanish (Q1321) adverbs.
+# Enter this query at https://query.wikidata.org/.
+
+SELECT
+  (REPLACE(STR(?lexeme), "http://www.wikidata.org/entity/", "") AS ?lexemeID)
+  ?adverb
+  ?diminutive
+  ?superlative
+
+WHERE {
+  ?lexeme dct:language wd:Q1321 ;
+    wikibase:lexicalCategory wd:Q380057 ;
+    wikibase:lemma ?adverb .
+
+  # MARK: Diminutive
+  OPTIONAL {
+    ?lexeme ontolex:lexicalForm ?diminutiveForm .
+    ?diminutiveForm ontolex:representation ?diminutive ;
+      wikibase:grammaticalFeature wd:Q108709 .
+  }
+
+  # MARK: Superlative
+  OPTIONAL {
+    ?lexeme ontolex:lexicalForm ?superlativeForm .
+    ?superlativeForm ontolex:representation ?superlative ;
+      wikibase:grammaticalFeature wd:Q1817208 .
+  }
+}

src/scribe_data/language_data_extraction/Spanish/prepositions/query_prepositions.sparql

@@ -0,0 +1,14 @@
+# tool: scribe-data
+# All Spanish (Q1321) prepositions.
+# Enter this query at https://query.wikidata.org/.
+
+SELECT
+  (REPLACE(STR(?lexeme), "http://www.wikidata.org/entity/", "") AS ?lexemeID)
+  ?preposition
+
+WHERE {
+  ?lexeme dct:language wd:Q1321 ;
+    wikibase:lexicalCategory wd:Q4833830 ;
+    wikibase:lemma ?preposition ;
+    FILTER(lang(?preposition) = "es") .
+}