ci: github python matrix didn't work, use nix instead (#96)

Drops test with Python 2.7, but that wasn't working with the previous configuration anyway.

README.md

@@ -45,7 +45,7 @@ Or add to your flake imports, and use the `default` package output.
 
 ### Install with NPM
 
-Requires Python version 3 or 2.7.
+Requires Python 3.8 or later.
 
 Install as a development dependency in a project that uses npm packages:
 
@@ -57,7 +57,7 @@ Or install globally:
 
 ### Or just copy the script
 
-Requires Python version 3 or 2.7.
+Requires Python 3.8 or later.
 
 If you do not use the above methods you can copy the
 [`git-format-staged`](./git-format-staged) script from this repository and

flake.nix

@@ -6,20 +6,51 @@
 
   outputs = { self, nixpkgs, systems }:
     let
-      eachSystem = nixpkgs.lib.genAttrs (import systems);
-      pkgs = eachSystem (system: nixpkgs.legacyPackages.${system});
+      eachSystem = callback: builtins.listToAttrs (builtins.map
+        (system: {
+          name = system;
+          value = callback (pkgs system) system;
+        })
+        (import systems));
+      pkgs = system: nixpkgs.legacyPackages.${system};
     in
     {
-      packages = eachSystem (system: {
-        default = pkgs.${system}.callPackage ./packages/git-format-staged.nix { };
+      packages = eachSystem (pkgs: system: {
+        default = pkgs.callPackage ./packages/git-format-staged.nix { };
       });
-      devShells = eachSystem (system: {
-        default = pkgs.${system}.mkShell {
-          nativeBuildInputs = with pkgs.${system}; [
-            nodejs_18
+
+      devShells = eachSystem (pkgs: system: {
+        default = pkgs.mkShell {
+          nativeBuildInputs = with pkgs; [
+            nodejs
             python3
           ];
         };
       });
+
+      # Run tests against maintained Python versions.
+      #
+      # Run tests with,
+      #
+      #     $ nix flake check --print-build-logs
+      #
+      checks = eachSystem (pkgs: system:
+        let
+          python_versions = with pkgs; [
+            python313
+            python312 # Python 3.12
+            python311
+            python310
+            python39 # Python 3.9
+            python38
+          ];
+        in
+        builtins.listToAttrs (builtins.map
+          (python3: rec {
+            name = builtins.replaceStrings [ "." ] [ "_" ] "test-python_${python3.version}";
+            value = pkgs.callPackage ./test/test.nix { inherit name python3; };
+          })
+          python_versions)
+      );
     };
 }

garnix.yaml

@@ -0,0 +1,5 @@
+# Configures builds on https://garnix.io/
+builds:
+  include:
+    - 'packages.x86_64-linux.*'
+    - 'checks.x86_64-linux.*'

git-format-staged

@@ -9,7 +9,7 @@
 # Usage: git-format-staged [OPTION]... [FILE]...
 # Example: git-format-staged --formatter 'prettier --stdin-filepath "{}"' '*.js'
 #
-# Tested with Python 3.10 and Python 2.7.
+# Tested with Python versions 3.8 - 3.13.
 #
 # Original author: Jesse Hallett <[email protected]>
 

test/helpers/git.ts

@@ -41,14 +41,14 @@ export async function formatStaged (
   repo: Repo,
   args: string // space-separated arguments, interpreted by shell
 ): Promise<Result> {
-  return run([BIN, args].join(' '), [], { cwd: repo.path, shell: true })
+  return run(["python3", BIN, args].join(' '), [], { cwd: repo.path, shell: true })
 }
 
 export async function formatStagedCaptureError (
   repo: Repo,
   args: string // space-separated arguments, interpreted by shell
 ): Promise<Result> {
-  return runCommand([BIN, args].join(' '), [], { cwd: repo.path, shell: true })
+  return runCommand(["python3", BIN, args].join(' '), [], { cwd: repo.path, shell: true })
 }
 
 export async function formatted (

test/test.nix

@@ -0,0 +1,40 @@
+{ name
+, fetchNpmDeps
+, git
+, gnused
+, nodejs
+, python3
+, stdenvNoCC
+}:
+
+let
+  src = ../.;
+  npmDeps = fetchNpmDeps {
+    inherit src;
+    name = "${name}-deps";
+    hash = "sha256-QzQZOwtGfKvIU33Bfc5fQ/FZTTezoRnxysUXyPbKXtg=";
+  };
+in
+stdenvNoCC.mkDerivation {
+  inherit name src;
+  nativeBuildInputs = [
+    git
+    nodejs
+    python3
+    gnused
+  ];
+  buildPhase = ''
+    npm install --cache "${npmDeps}";
+
+    # Patch node script interpreter lines because the nix build environment does
+    # not have a /usr/bin/env
+    sed -i --follow-symlinks \
+      '1s|#!/usr/bin/env node|#!${nodejs}/bin/node|' \
+      node_modules/.bin/*
+
+    npm test | tee test_output
+  '';
+  installPhase = ''
+    cp test_output "$out"
+  '';
+}