Merge pull request #9 from entropia/cloud-init

cloud-init installer iso

checks/cloudInitImage.nix

@@ -0,0 +1,10 @@
+{ self, inputs, ... }:
+let
+  inherit (inputs.nixpkgs) lib;
+in
+{
+  perSystem = { system, ... }: {
+    checks = lib.optionalAttrs (system == "x86_64-linux") 
+      (lib.mapAttrs' (name: value: lib.nameValuePair "cloudInitImage-${name}" value) self.cloudInitImages.${system});
+  };
+}

checks/default.nix

@@ -2,5 +2,6 @@
   imports = [
     ./devShells.nix
     ./nixosConfigurations.nix
+    ./cloudInitImage.nix
   ];
 }

flake.nix

@@ -26,6 +26,8 @@
       ./modules
       ./pkgs
       ./checks
+      ./lib/cloud-init.nix
+      ./flakeModules
     ];
 
     perSystem = { pkgs, inputs', ... }: {

flakeModules/cloud-init.nix

@@ -0,0 +1,13 @@
+{ lib, flake-parts-lib, ... }:
+let
+  inherit (lib) mkOption types ;
+  inherit (flake-parts-lib) mkTransposedPerSystemModule ;
+in
+mkTransposedPerSystemModule {
+  name = "cloudInitImages";
+  option = mkOption {
+    type = types.lazyAttrsOf types.package;
+    default = { };
+  };
+  file = ./cloud-init.nix;
+}

flakeModules/default.nix

@@ -0,0 +1,5 @@
+{
+  imports = [
+    ./cloud-init.nix
+  ];
+}

lib/cloud-init.nix

@@ -0,0 +1,60 @@
+{ inputs, ... }: {
+  perSystem = { system, ... }: {
+    cloudInitImages.default = (inputs.nixpkgs.lib.nixosSystem {
+      inherit system;
+      specialArgs = { inherit inputs; };
+      modules = [
+        ({ config, lib, pkgs, modulesPath, ... }: {
+          imports = [
+            ../profiles/base
+            (modulesPath + "/profiles/minimal.nix")
+            (modulesPath + "/profiles/qemu-guest.nix")
+            (modulesPath + "/installer/cd-dvd/iso-image.nix")
+            inputs.colmena.nixosModules.deploymentOptions
+            inputs.sops-nix.nixosModules.default
+          ];
+
+          nixpkgs.hostPlatform = system;
+          system.stateVersion = "24.05";
+
+          isoImage = {
+            makeEfiBootable = true;
+            forceTextMode = true;
+            isoBaseName = "nixos-cloudinit-entropia";
+          };
+
+          networking = {
+            useDHCP = true;
+            useNetworkd = true;
+          };
+
+          services.cloud-init = {
+            enable = true;
+            network.enable = true;
+            settings = {
+              cloud_init_modules = lib.mkForce [
+                "seed_random"
+                "bootcmd"
+                "resolv_conf"
+                "rsyslog"
+                "users-groups"
+                "ssh"
+              ];
+
+              cloud_config_modules = lib.mkForce [
+                "set-passwords"
+                "timezone"
+                "disable_ec2_metadata"
+              ];
+
+              cloud_final_modules = lib.mkForce [
+                "final-message"
+              ];
+
+            };
+          };
+        })
+      ];
+    }).config.system.build.isoImage;
+  };
+}