-
Notifications
You must be signed in to change notification settings - Fork 6
/
xTerior.m
1356 lines (968 loc) · 66.3 KB
/
xTerior.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(************************************************************************)
(* This file was generated automatically by the Mathematica front end. *)
(* It contains Initialization cells from a Notebook file, which *)
(* typically will have the same name as this file except ending in *)
(* ".nb" instead of ".m". *)
(* *)
(* This file is intended to be loaded into the Mathematica kernel using *)
(* the package loading commands Get or Needs. Doing so is equivalent *)
(* to using the Evaluate Initialization Cells menu command in the front *)
(* end. *)
(* *)
(* DO NOT EDIT THIS FILE. This entire file is regenerated *)
(* automatically each time the parent Notebook file is saved in the *)
(* Mathematica front end. Any changes you make to this file will be *)
(* overwritten. *)
(************************************************************************)
(* ::Input::Initialization:: *)
xAct`xTerior`$xTensorVersionExpected={"1.1.2",{2015,8,23}};
xAct`xTerior`$Version={"0.9.1",{2019,5,17}};
(* ::Input::Initialization:: *)
(* xTerior: exterior calculus in Differential Geometry *)
(* Copyright (C) 2013-2019 Alfonso Garcia-Parrado Gomez-Lobo and Leo C. Stein *)
(* This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License,or (at your option) any later version.
This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
You should have received a copy of the GNU General Public License along with this program; if not, write to the Free Software Foundation, Inc., 59 Temple Place-Suite 330, Boston, MA 02111-1307, USA.
*)
(* ::Input::Initialization:: *)
(* :Title: xTerior *)
(* :Author: Alfonso Garcia-Parrado Gomez-Lobo and Leo C. Stein *)
(* :Summary: exterior calculus in Differential Geometry *)
(* :Brief Discussion:
- xTerior extends xAct to work with differentiable forms in general manifolds.
- Introduces the exterior algebra, the exterior derivative, the Hodge dual, the connection and curvature forms for an arbitrary connection, the exterior covariant derivative.
*)
(* :Context: xAct`xTerior` *)
(* :Package Version: 0.9.1 *)
(* :Copyright: Alfonso Garcia-Parrado Gomez-Lobo and Leo C. Stein (2013-2019) *)
(* :History: See xTerior.History *)
(* :Keywords: *)
(* :Source: xTerior.nb *)
(* :Warning: *)
(* :Mathematica Version: 9.0 and later *)
(* :Limitations:
- ?? *)
(* ::Input::Initialization:: *)
With[{xAct`xTerior`Private`xTeriorSymbols=DeleteCases[Join[Names["xAct`xTerior`*"],Names["xAct`xTerior`Private`*"]],"$Version"|"xAct`xTerior`$Version"|"$xTensorVersionExpected"|"xAct`xTerior`$xTensorVersionExpected"]},
Unprotect/@xAct`xTerior`Private`xTeriorSymbols;
Clear/@xAct`xTerior`Private`xTeriorSymbols;
]
(* ::Input::Initialization:: *)
If[Unevaluated[xAct`xCore`Private`$LastPackage]===xAct`xCore`Private`$LastPackage,xAct`xCore`Private`$LastPackage="xAct`xTerior`"];
(* ::Input::Initialization:: *)
BeginPackage["xAct`xTerior`",{"xAct`xCoba`","xAct`xTensor`","xAct`xPerm`","xAct`xCore`"}]
(* ::Input::Initialization:: *)
If[Not@OrderedQ@Map[Last,{xAct`xTerior`$xTensorVersionExpected,xAct`xTensor`$Version}],Throw@Message[General::versions,"xTensor",xAct`xTensor`$Version,xAct`xTerior`$xTensorVersionExpected]]
(* ::Input::Initialization:: *)
Print[xAct`xCore`Private`bars]
Print["Package xAct`xTerior` version ",xAct`xTerior`$Version[[1]],", ",xAct`xTerior`$Version[[2]]];
Print["Copyright (C) 2013-2019, Alfonso Garcia-Parrado Gomez-Lobo and Leo C. Stein, under the General Public License."];
(* ::Input::Initialization:: *)
Off[General::shdw]
xAct`xTerior`Disclaimer[]:=Print["These are points 11 and 12 of the General Public License:\n\nBECAUSE THE PROGRAM IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY FOR THE PROGRAM, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES PROVIDE THE PROGRAM `AS IS\.b4 WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE PROGRAM IS WITH YOU. SHOULD THE PROGRAM PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL NECESSARY SERVICING, REPAIR OR CORRECTION.\n\nIN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR REDISTRIBUTE THE PROGRAM AS PERMITTED ABOVE, BE LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE THE PROGRAM (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A FAILURE OF THE PROGRAM TO OPERATE WITH ANY OTHER PROGRAMS), EVEN IF SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES."]
On[General::shdw]
(* ::Input::Initialization:: *)
If[xAct`xCore`Private`$LastPackage==="xAct`xTerior`",
Unset[xAct`xCore`Private`$LastPackage];
Print[xAct`xCore`Private`bars];
Print["These packages come with ABSOLUTELY NO WARRANTY; for details type Disclaimer[]. This is free software, and you are welcome to redistribute it under certain conditions. See the General Public License for details."];
Print[xAct`xCore`Private`bars]]
(* ::Input::Initialization:: *)
$PrePrint=ScreenDollarIndices;
(* ::Input::Initialization:: *)
Unprotect@PD;
PD/:ManifoldOfCovD@PD=.
Protect@PD;
(* ::Input::Initialization:: *)
(* Definition and undefinition of a differential form (just a wrapper for DefTensor with the option GradeOfTensor\[Rule]{Wedge})*)
DefDiffForm::usage="DefDiffForm[form[inds], mani, Deg] defines a tensor valued differential form of degree deg on the manifold mani";
UndefDiffForm::usage="UndefDiffForm[form] undefines the differential form form";
(* Grade of a differential form *)
Deg::usage="Deg[form] returns the grade of a differential form";
DiffFormQ::usage="DiffFormQ is an option for LieToCovD which specifies whether the expression which is acted upon should be regarded as a differential form or not. This is an option added by xTerior and it is not present any other package using LieToCovD.";
(* Exterior derivative and exterior covariant derivative *)
Diff::usage="Diff[form] computes the exterior derivative of form. Diff[form,covd] computes the exterior covariant derivative of form with respect to the covariant derivative covd.";
FindPotential::usage="FindPotential[form, point, chart] uses the Poincar\[EAcute] lemma to compute a potential for a closed form form (no checks are carried out to ensure that the form is actually closed). The form must be written in some explicit coordinates belonging to chart and the argument point is the point, assumed to be in the same coordinate chart as form, which defines a star-shaped region where the potential is differentiable. A change in the point will give in general a different potential";
(* Computation of the exterior covariant derivative *)
ChangeExtD::usage="ChangeExtD[expr,cd1,cd2] expresses the exterior covariant derivative taken with respect to the connection defined by the covariant derivative cd1 in terms of the exterior covariant derivative taken with respect to the connection defined by the covariant derivative cd2";
(* Computation of the generalized (index-free) covariant derivative *)
ChangeGenCovD::usage="ChangeGenCovD[expr,cd1,cd2] expresses the generalized covariant derivative taken with respect to the connection defined by the covariant derivative cd1 in terms of the generalized covariant derivative taken with respect to the connection defined by the covariant derivative cd2";
(* Hodge dual *)
Hodge::usage="Hodge[metric][expr] is the Hodge dual of expr defined with respect to metric";
ExpandHodgeDual::usage="ExpandHodgeDual[expr,Coframe[mani],g] expands out all the Hodge duals of the exterior powers of Coframe[mani], defined with respect to the metric g. If the manifold tag mani is dropped, then all the instances of Coframe are expanded. The Coframe label can be replaced by dx if we are using the holonomic coframe.";
(* Co-differential *)
Codiff::usage="Codiff[metric][form] is the co-differential of form computed with respect to metric";
(* Expansion of the co-differential *)
CodiffToDiff::usage="CodiffToDiff[expr] replaces all the instances of the co-differential in expr by their expansion in terms of the exterior derivative.";
(* Interior contraction *)
Int::usage="Int[v][form] is the interior contraction of form with the vector (rank 1-tensor) v";
(* Lie derivative on forms *)
CartanD::usage="CartanD[v][form] is the Cartan derivative of form with respect to the vector (rank 1-tensor) v. CartanD[v][form,covd] is the Cartan derivative with respect to the covariant derivative covd.";
(* Cartan formula for Lie derivatives *)
CartanDToDiff::usage="CartanDToDiff[expr] replaces the Cartan derivative of all the differential forms in expr by their expansion obtained by means of the Cartan formula";
(* Put derivations into canonical order *)
SortDerivations::usage="SortDerivations[expr] brings expr into a new expression where all the derivations (exterior derivative, Lie derivative and interior contraction) are written in a canonical order. The default left-to-right order is defined by the variable $DerivationSortOrder";
$DerivationSortOrder::usage="$DerivationSortOrder is a global variable which encodes the default ordering of the three derivatives Int, LieD and Diff. The default is {LieD,Int,Diff}";
(* Variational derivative on forms *)
FormVarD::usage="FormVarD[form,metric][expr] computes the variational derivative of expr, which must be a n-form with n the manifold dimension, with respect to form. In the computation, exterior derivatives are transformed into co-differentials taken with respect of metric.";
(* Canonical forms on the frame bundle *)
Coframe::usage="Coframe[mani] is the set of canonical 1-forms defined in the frame bundle arising from the manifold mani";
dx::usage="dx[mani] represents a holonomic co-frame in the manifold mani.";
(* Holonomic & anholonomic frames *)
PDFrame::usage="PDFrame[mani] represents a holonomic frame in the manifold mani.";
eFrame::usage="eFrame[mani] represents a frame in the manifold mani.";
(* Koszul connection *)
Koszul::usage="Koszul is the head used to introduce the Koszul operator. The latter is constructed by appending this head to the xTensor symbol used to represent a covariant derivative";
ExpandKoszul::usage="ExpandKoszul[expr,cd1,cd2] expands Koszul derivations of frame or co-frame elements with respect to cd1 into Christoffel tensors relating the covariant derivatives cd1 and cd2";
ExpandCovD::usage="ExpandCovD[expr,cd,chart] expands all the generalized covariant derivatives of rank 1 tensors in terms of the Koszul derivatives with respect to elements of a holonomic frame associated to a coordinate chart";
(* The connection 1-form *)
ConnectionForm::usage="ConnectionForm[cd,vbundle] represents the connection 1-form associated to the covariant derivatives cd defined in the bundle vbundle. If vbundle is the tangent bundle of a differentiable manifold then ConnectionForm is automatically replaced by ChristoffelForm (see the on-line help of ChristoffelForm for further details).";
(* The curvature 2-form *)
CurvatureForm::usage="CurvatureForm[cd,vbundle] represents the curvature 2-form associated to the covariant derivative cd. If vbundle is the tangent bundle of a differentiable manifold then CurvatureForm is replaced by RiemannForm";
(* Connection 2-form for a connection in a frame bundle*)
ChristoffelForm::usage="ChristoffelForm[cd] is the connection 1-form associated to the covariant derivative cd which is a covariant derivative in the tangent bundle of a manifold";
(* Curvature 2-form for a connection in a frame bundle *)
RiemannForm::usage="RiemannForm[cd] is the curvature 2-form associated to the covariant derivative cd which is a covariant derivative in the frame bundle of a manifold";
(* Transformation of the connection form to the connection tensor *)
ConnectionFormToTensor::usage="ConnectionFormToTensor[expr,covd,frame] transforms all instances of the connection form into the (A)Christoffel tensor which relates the covariant derivative defining the connection form and covd. The variable frame can take the value of either Coframe or dx. If the (A)Christoffel tensor does not exist it is created automatically.";
CurvatureFormToTensor::usage="CurvatureFormToTensor[expr,frame] transforms all the instances of the curvature form into the related Riemann or FRiemann tensor, inserting the corresponding frame (either Coframe or dx).";
ChangeCurvatureForm::usage="ChangeCurvatureForm[curvature,cd1,cd2] writes the curvature 2-form curvature[cd1,vbundle] in terms of the curvature 2-form curvature[cd2,vbundle]";
(* The torsion 2-form *)
TorsionForm::usage="TorsionForm[cd] represents the torsion 2-form arising from the covariant derivative cd (cd must be defined on the tangent bundle of a manifold)";
(* Cartan structure equations *)
UseCartan::usage="UseCartan[expr,covd] expands all the instances of the Diff using the Cartan structure equations for the connection arising from covd. In this way it is possible to expand the exterior derivative of a co-frame, a torsion 2-form and the curvature 2-form. If covd is the Levi-Civita connection of a metric, then the exterior derivatives of that metric and its volume element are expanded too. UseCartan[expr,PD] expands all instances of the exterior derivative in terms of partial derivatives defined in the list of manifolds returned by ManifoldsOf[expr]. It is possible to specify a custom list of manifolds as a third argument in the form UseCartan[expr,PD,{M1,M2,..}]";
(* Zero forms *)
ZeroDegQ::usage="ZeroDegQ[expr] returns True if the degree of expr is zero";
UseDimensionStart::usage="UseDimensionStart[] is an instruction that, when issued, makes any expression with degree greater than the manifold dimension equal to zero.";
UseDimensionStop::usage="UseDimensionStop[] cancels the action of UseDimensionStart[]";
(* Integration of differential forms over manifolds with boundary *)
FormIntegrate::usage="FormIntegrate[form, M] represents the integration of the given differential form, of degree n, over the n-dimensional manifold M with boundary.";
UseStokes::usage="UseStokes[expr, M] converts subexpressions FormIntegrate[Diff[form], M] in expr into FormIntegrate[form, ManifoldBoundary[M]], reducing n-dimensional integration to (n-1)-integration. UseStokes[expr, form] converts subexpressions FormIntegrate[form, ManifoldBoundary[M]] in expr into FormIntegrate[Diff[form], M]. UseStokes[expr] performs UseStokes[expr, M] wherever possible in expr, to reduce dimensionality of integration.";
(* ::Input::Initialization:: *)
Begin["`Private`"]
(* ::Input::Initialization:: *)
$ContextPath
(* ::Input::Initialization:: *)
DefProduct[Wedge,
AssociativeProductQ->True,
CommutativityOfProduct->"SuperCommutative",
GradedProductQ->True,
IdentityElementOfProduct->1,
ScalarsOfProduct->(SameQ[Grade[#,Wedge],0]&),
DefInfo->Null
];
(* ::Input::Initialization:: *)
Wedge/:GradeOfProduct[Times,Wedge]=0;
(* ::Input::Initialization:: *)
Deg[expr_]:=Grade[expr,Wedge];
(* ::Input::Initialization:: *)
Unprotect@Dagger;
Dagger@expr_Wedge:=Dagger/@expr;
Protect@Dagger;
(* ::Input::Initialization:: *)
(*Code added by Jos\[EAcute]*)
$UseDimensionsQ=False;
$DimensionsZeroForms={};
SetZeroForm[form_]:=If[GradeOfTensor[form,Wedge]>Plus@@(DimOfManifold/@DependenciesOfTensor[form]),form[___]=0;AppendTo[$DimensionsZeroForms,form]];
UnsetZeroForm[form_]:=Unset[form[___]];
UseDimensionStart[]:=Module[{},If[$UseDimensionsQ,Return[]];
$UseDimensionsQ=True;
(*Forms whose degree is greater than the dimension*)SetZeroForm/@$Tensors;
(*Expressions which are wedge products*)HoldPattern@Wedge[expr__]:=0/;(Plus@@(Grade[#,Wedge]&/@{expr})>(Plus@@(DimOfManifold/@Union@Flatten[DependenciesOf/@{expr}])));
(*Expressions which are exterior derivatives*)HoldPattern@Diff[expr_,PD]:=0/;(1+Plus@@(Grade[#,Wedge]&/@{expr})>(Plus@@(DimOfManifold/@DependenciesOf[expr])));
HoldPattern@Diff[expr_,covd_]:=0/;(1+Plus@@(Grade[#,Wedge]&/@{expr})>(Plus@@(DimOfManifold/@DependenciesOf[expr])));]
UseDimensionStop[]:=Module[{},If[!$UseDimensionsQ,Return[]];
$UseDimensionsQ=False;
UnsetZeroForm/@Union@$DimensionsZeroForms;
HoldPattern@Wedge[expr__]=.;
HoldPattern@Diff[expr_,PD]=.;
HoldPattern@Diff[expr_,covd_]=.;]
(* xTensions *)
xTension["xTerior`",DefTensor,"End"]:=DefTensorUseDimensions;
DefTensorUseDimensions[tensor_[inds___],__]:=If[$UseDimensionsQ,SetZeroForm[tensor]];
xTension["xTerior`",UndefTensor,"Beginning"]:=UndefTensorUseDimensions;
UndefTensorUseDimensions[tensor_]:=If[$UseDimensionsQ,UnsetZeroForm[tensor]];
(* ::Input::Initialization:: *)
(* Grade of a CTensor with respect to Wedge *)
CTensor/:Grade[expr_CTensor,Wedge]:=Module[{list,grades,comps=First@expr},
list=Flatten[{comps}];
grades=Grade[#,Wedge]&/@list;
If[Length@Tally[grades]==1,grades[[1]],$Failed]
];
(* ::Input::Initialization:: *)
(* Contracted wedge product of CTensor objects *)
Wedge[ctensor1_CTensor[left1___,a_,right1___],ctensor2_CTensor[left2___,-a_,right2___]]:=Module[{n1=Length[{left1,a}],n2=Length[{left2,-a}],res},res=xAct`xCoba`Private`CTensorContract[ctensor1,ctensor2,{n1,n2},Wedge];
res[left1,right1,left2,right2]/;FreeQ[res,$Failed]];
Wedge[ctensor1_CTensor[left1___,-a_,right1___],ctensor2_CTensor[left2___,a_,right2___]]:=Module[{n1=Length[{left1,a}],n2=Length[{left2,-a}],res},res=xAct`xCoba`Private`CTensorContract[ctensor1,ctensor2,{n1,n2},Wedge];
res[left1,right1,left2,right2]/;FreeQ[res,$Failed]];
(* ::Input::Initialization:: *)
(*signatureOrZero[indices_]:=If[DuplicateFreeQ[indices],Signature[Ordering[indices]],0];*)
simplifyBasisWedge[expr_]:=expr/.wed_Wedge:>simplifyBasisWedge1[wed];
(*simplifyBasisWedge1[HoldPattern[Wedge[factors:((head:((xAct`xTerior`Coframe|xAct`xTerior`dx)[_]))[_]..)]]]:=With[{indices=First/@{factors}},signatureOrZero[indices] Wedge@@(head/@Sort[indices])];*)
simplifyBasisWedge1[HoldPattern[expr:Wedge[factors:Blank[] ..]]]:=Module[{indices=FindFreeIndices[expr]},If[indices===IndexList[],expr,$Failed]];
(* Wedge product of general CTensor objects *)
CTensorWedge[]:=1;
CTensorWedge[ctensors__CTensor]:=CTensor[simplifyBasisWedge[xAct`xCoba`Private`tensorproduct[Wedge]@@#1],Join@@#2,Plus@@#3]&@@Transpose[List@@@{ctensors}];
CTensorWedge[___,Zero,___]:=Zero;
Wedge[ctensor1_CTensor[inds1___],ctensor2_CTensor[inds2___]]:=CTensorWedge[ctensor1,ctensor2][inds1,inds2]/;xAct`xTensor`Private`TakePairs[{inds1,inds2}]==={}
Wedge[ctensor1_CTensor,ctensor2_CTensor]:=CTensorWedge[ctensor1,ctensor2]
(* ::Input::Initialization:: *)
Wedge[basis:(Coframe|dx)[_][_?CIndexQ],CTensor[array_,bases_List,addweight_][b__]]:=CTensor[Wedge[basis,array],bases,addweight][b]
Wedge[CTensor[array_,bases_List,addweight_][b__],basis:(Coframe|dx)[_][_?CIndexQ]]:=CTensor[Wedge[array,basis],bases,addweight][b]
(* ::Input::Initialization:: *)
FormBases[CTensor[array_,__]]:=DeleteDuplicates[xAct`xPerm`Private`nosign/@Cases[array,(Coframe|dx)[_][{_,frame_}]:>frame,{0,Infinity}]]
Wedge[(basis:(Coframe|dx)[_])[ind_],ctensor_CTensor[inds___]]:=With[{frames=FormBases[ctensor]},Wedge[ToCTensor[basis,frames][ind],ctensor[inds]]/;Length[frames]===1]
Wedge[ctensor_CTensor[inds___],(basis:(Coframe|dx)[_])[ind_]]:=With[{frames=FormBases[ctensor]},Wedge[ctensor[inds],ToCTensor[basis,frames][ind]]/;Length[frames]===1]
(* ::Input::Initialization:: *)
CTensor/:(basis:(Coframe|dx)[_])[a_] (ctensor:CTensor[_,bases_List,_][l___,-a_,___]):=ToCTensor[basis,{-bases[[Length[{l,-a}]]]}][a] ctensor
(* ::Input::Initialization:: *)
CTensor/:HoldPattern[Wedge[lw___,(basis:(Coframe|dx)[_])[a_] ,rw___] (ctensor:CTensor[_,bases_List,_][l___,-a_,___])]:=Wedge[lw,ToCTensor[basis,{-bases[[Length[{l,-a}]]]}][a],rw] ctensor
(* ::Input::Initialization:: *)
Wedge[ten_,CTensor[array_,bases_List,addweight_][b__]]:=CTensor[Wedge[ten,array],bases,addweight][b]/;FindFreeIndices@ten===IndexList[]
Wedge[CTensor[array_,bases_List,addweight_][b__],ten_]:=CTensor[Wedge[array,ten],bases,addweight][b]/;FindFreeIndices@ten===IndexList[]
(* ::Input::Initialization:: *)
$DefInfoQ=False;
(* ::Input::Initialization:: *)
DefProduct[CircleTimes,
AssociativeProductQ->True,
IdentityElementOfProduct->1,
GradedProductQ->True,
ScalarsOfProduct->(SameQ[Grade[#,CircleTimes],0]&),
PrintAs->"\[CircleTimes]"
]
(* ::Input::Initialization:: *)
$DefInfoQ=True;
(* ::Input::Initialization:: *)
CircleTimes/:GradeOfProduct[Times,CircleTimes]=0;
(* ::Input::Initialization:: *)
CircleTimes/:GradeOfTensor[head_,CircleTimes]:=GradeOfTensor[head,Wedge];
(* ::Input::Initialization:: *)
CircleTimes/:Grade[Diff[expr_,_],CircleTimes]:=Grade[expr,CircleTimes]+1;
(* ::Input::Initialization:: *)
CircleTimes/:Grade[Hodge[metricg_][expr_],CircleTimes]:=DimOfVBundle[VBundleOfMetric[metricg]]-Grade[expr,CircleTimes];
(* ::Input::Initialization:: *)
Unprotect@Dagger;
Dagger@expr_CircleTimes:=Dagger/@expr;
Protect@Dagger;
(* ::Input::Initialization:: *)
(* Grade of a CTensor with respect to CircleTimes *)
CTensor/:Grade[expr_CTensor,CircleTimes]:=Module[{list,grades,comps=First@expr},
list=Flatten[{comps}];
grades=Grade[#,CircleTimes]&/@list;
If[Length@Tally[grades]==1,grades[[1]],$Failed]
];
(* ::Input::Initialization:: *)
(* Algebra with unit element *)
xAct`xCoba`Private`tensorproduct[CircleTimes][]=1;
(* ::Input::Initialization:: *)
(* Contracted CircleTimes product of CTensor objects *)
CircleTimes[ctensor1_CTensor[left1___,a_,right1___],ctensor2_CTensor[left2___,-a_,right2___]]:=Module[{n1=Length[{left1,a}],n2=Length[{left2,-a}],res},res=xAct`xCoba`Private`CTensorContract[ctensor1,ctensor2,{n1,n2},CircleTimes];
res[left1,right1,left2,right2]/;FreeQ[res,$Failed]];
CircleTimes[ctensor1_CTensor[left1___,-a_,right1___],ctensor2_CTensor[left2___,a_,right2___]]:=Module[{n1=Length[{left1,a}],n2=Length[{left2,-a}],res},res=xAct`xCoba`Private`CTensorContract[ctensor1,ctensor2,{n1,n2},CircleTimes];
res[left1,right1,left2,right2]/;FreeQ[res,$Failed]];
(* ::Input::Initialization:: *)
simplifyBasisCircleTimes[expr_]:=expr/.wed_CircleTimes:>simplifyBasisCircleTimes1[wed];
simplifyBasisCircleTimes1[HoldPattern[expr:CircleTimes[factors:Blank[] ..]]]:=Module[{indices=FindFreeIndices[expr]},If[indices===IndexList[],expr,$Failed]];
(* CircelTimes product of general CTensor objects *)
CTensorCircleTimes[]:=1;
CTensorCircleTimes[ctensors__CTensor]:=CTensor[simplifyBasisCircleTimes[xAct`xCoba`Private`tensorproduct[CircleTimes]@@#1],Join@@#2,Plus@@#3]&@@Transpose[List@@@{ctensors}];
CTensorCircleTimes[___,Zero,___]:=Zero;
CircleTimes[ctensor1_CTensor[inds1___],ctensor2_CTensor[inds2___]]:=CTensorCircleTimes[ctensor1,ctensor2][inds1,inds2]/;xAct`xTensor`Private`TakePairs[{inds1,inds2}]==={}
CircleTimes[ctensor1_CTensor,ctensor2_CTensor]:=CTensorCircleTimes[ctensor1,ctensor2]
(* ::Input::Initialization:: *)
CircleTimes[ten_,CTensor[array_,bases_List,addweight_][b__]]:=CTensor[CircleTimes[ten,array],bases,addweight][b]/;FindFreeIndices@ten===IndexList[]
CircleTimes[CTensor[array_,bases_List,addweight_][b__],ten_]:=CTensor[CircleTimes[array,ten],bases,addweight][b]/;FindFreeIndices@ten===IndexList[]
(* ::Input::Initialization:: *)
DefDiffForm[form_,mani_,deg_,options___?OptionQ]:=
(DefTensor[form,mani,GradeOfTensor->{Wedge->deg},options];
)
(* ::Input::Initialization:: *)
DefDiffForm[form_,mani_,deg_,sym_,options___?OptionQ]:=
(DefTensor[form,mani,sym,GradeOfTensor->{Wedge->deg},options];
)
(* ::Input::Initialization:: *)
Options@DefDiffForm:=Options@DefTensor;
(* ::Input::Initialization:: *)
UndefDiffForm:=UndefTensor;
(* ::Input::Initialization:: *)
Protect[DefDiffForm,UndefDiffForm];
(* ::Input::Initialization:: *)
Options[DefGradedDerivation]={
PrintAs->Identity,
Master->Null
};
(* ::Input::Initialization:: *)
GradeOfDerivation[head_[v_,rest___],prod_]:=GradeOfDerivation[head,prod]+Grade[v,prod];
(* ::Input::Initialization:: *)
DefGradedDerivation[der_,prod_?ProductQ,dergrade_:0,options:OptionsPattern[]]:=With[{head=SubHead[der]},
Module[{pa},
{pa}=OptionValue[{PrintAs}];
(* DefInertHead will take care of scalar-homogeneity and linearity *)
DefInertHead[der,
LinearQ->True,
ContractThrough->{delta},
PrintAs->pa,DefInfo->Null];
(* Other properties of a derivation *)
MakeDerivation[head,der,NoPattern[der],prod,dergrade];
(* Nonatomic derivation *)
If[der=!=head,
(* additivity in the vector slot (but not homogeneity!) *)
head[0][__]:=0;
head[v_Plus][args__]:=head[#][args]&/@v;
(* Subscript vector argument for formatting *)
If[pa===Identity,pa=PrintAs[head]];
head/:MakeBoxes[head[v_][form_],StandardForm]:=xAct`xTensor`Private`interpretbox[head[v][form],RowBox[{SubscriptBox[pa,MakeBoxes[v,StandardForm]],"[",MakeBoxes[form,StandardForm],"]"}]];
]
]
];
(* ::Input::Initialization:: *)
MakeDerivation[head_,derL_,derR_,prod_,dergrade_]:=With[{grade=GradeOfDerivation[derR,prod]},
(* Addition of grades in algebra *)
head/:GradeOfDerivation[head,prod]:=dergrade;
head/:Grade[derL[expr_,___],prod]:=Grade[expr,prod]+grade;
(* The (graded) Leibniz rule *)
derL[expr_prod,rest___]:=With[{sumgrades=FoldList[Plus,0,Grade[#,Wedge]&/@List@@expr]},
Sum[
(-1)^(grade * sumgrades[[i]] )
MapAt[derR[#,rest]&,expr,i],
{i,1,Length[expr]}
]
];
(* QUESTION: Agreement with a regular derivative when acting on scalar functions?? *)
derL[func_?ScalarFunctionQ[args__],rest___]:=xAct`xTensor`Private`multiD[derR[#,rest]&,func[args]];
(* Dependencies *)
If[!AtomQ[derR],
head/:DependenciesOfInertHead[derL]:=DependenciesOf[First[derR]]
]
];
(* ::Input::Initialization:: *)
DefGradedDerivation[Diff,Wedge,+1,PrintAs->"d"];
(* ::Input::Initialization:: *)
Diff[expr_]:=Diff[expr,PD]
(* ::Input::Initialization:: *)
Diff/:MakeBoxes[Diff[form_,PD?CovDQ],StandardForm]:=xAct`xTensor`Private`interpretbox[Diff[form,PD],RowBox[{PrintAs[Diff],"[",MakeBoxes[form,StandardForm],"]"}]];
Diff/:MakeBoxes[Diff[form_,cd_?CovDQ],StandardForm]:=xAct`xTensor`Private`interpretbox[Diff[form,cd],RowBox[{SuperscriptBox[PrintAs[Diff],Last@SymbolOfCovD[cd]],"[",MakeBoxes[form,StandardForm],"]"}]];
(* ::Input::Initialization:: *)
Diff[expr_?ArrayQ,cd_]:=Diff[#,cd]&/@expr;
Diff[expr_Equal,cd_]:=Diff[#,cd]&/@expr;
(* ::Input::Initialization:: *)
Diff[expr_Diff,PD]:=0
(* ::Input::Initialization:: *)
Diff[_Basis,PD]:=0;
(* ::Input::Initialization:: *)
(* This produces expanded expressions and is much faster when there are many scalars *)
notZero=0=!=#&
Diff[expr_Times,cd_]:=Module[{grades=Grade[#,Wedge]&/@List@@expr,pos,scalar,form},
pos=Position[grades,_?notZero,1,Heads->False];
Which[
Length[pos]>1,
Throw[Message[Diff::error1,"Found Times product of nonscalar forms: ",expr]],
Length[pos]===1,
pos=pos[[1,1]];
scalar=Delete[expr,{pos}];
form=expr[[pos]];
scalar Diff[form,cd]+diff0[scalar,cd,form],
Length[pos]===0,
diff0[expr,cd]
]
];
(* Only scalars *)
diff0[scalar_Times,cd_]:=Sum[MapAt[Diff[#,cd]&,scalar,i],{i,1,Length[scalar]}];
diff0[scalar_,cd_]:=Diff[scalar,cd];
(* Scalars and a form *)
diff0[scalar_Times,cd_,form_]:=Sum[MapAt[diff0[#,cd,form]&,scalar,i],{i,1,Length[scalar]}];
diff0[scalar_,cd_,form_]:=Wedge[Diff[scalar,cd],form];
(* ::Input::Initialization:: *)
Diff[x_?ConstantQ,cd_]:=0;
(* ::Input::Initialization:: *)
Diff/:HoldPattern[Dagger[Diff[expr_,cd_]]]:=Diff[Dagger[expr],cd];
(* ::Input::Initialization:: *)
Diff[CTensor[array_,bases_List,weight_][inds__],cd_]:=CTensor[Diff[array,cd],bases,weight][inds];
(* ::Input::Initialization:: *)
xTensorQ@Coframe[mani_?ManifoldQ]^=True;
SlotsOfTensor[Coframe[mani_?ManifoldQ]]^:={Tangent@mani};
Coframe/:GradeOfTensor[Coframe[mani_?ManifoldQ],Wedge]=1;
SymmetryGroupOfTensor[Coframe[mani_?ManifoldQ]]^=StrongGenSet[{},GenSet[]];
DefInfo[Coframe[mani_?ManifoldQ]]^={"General co-frame",""};
DependenciesOfTensor[Coframe[mani_?ManifoldQ]]^:={mani};
HostsOf[Coframe[mani_?ManifoldQ]]^={};
TensorID[Coframe[mani_?ManifoldQ]]^={};
PrintAs[Coframe[mani_?ManifoldQ]]^="\[Theta]";
(* ::Input::Initialization:: *)
xTensorQ@dx[mani_?ManifoldQ]^=True;
SlotsOfTensor[dx[mani_?ManifoldQ]]^:={Tangent@mani};
dx/:GradeOfTensor[dx[mani_?ManifoldQ],Wedge]=1;
SymmetryGroupOfTensor[dx[mani_?ManifoldQ]]^=StrongGenSet[{},GenSet[]];
DefInfo[dx[mani_?ManifoldQ]]^={"General co-frame",""};
DependenciesOfTensor[dx[mani_?ManifoldQ]]^:={mani};
HostsOf[dx[mani_?ManifoldQ]]^={};
TensorID[dx[mani_?ManifoldQ]]^={};
PrintAs[dx[mani_?ManifoldQ]]^="dx";
(* ::Input::Initialization:: *)
Diff[dx[mani_?ManifoldQ][ind_],PD]:=0;
(* ::Input::Initialization:: *)
xTensorQ@eFrame[mani_?ManifoldQ]^=True;
SlotsOfTensor[eFrame[mani_?ManifoldQ]]^:={-Tangent@mani};
eFrame/:GradeOfTensor[eFrame[mani_?ManifoldQ],CircleTimes]=1;
SymmetryGroupOfTensor[eFrame[mani_?ManifoldQ]]^=StrongGenSet[{},GenSet[]];
DefInfo[eFrame[mani_?ManifoldQ]]^={"General frame",""};
DependenciesOfTensor[eFrame[mani_?ManifoldQ]]^:={mani};
HostsOf[eFrame[mani_?ManifoldQ]]^={};
TensorID[eFrame[mani_?ManifoldQ]]^={};
PrintAs[eFrame[mani_?ManifoldQ]]^="e";
(* ::Input::Initialization:: *)
xTensorQ@PDFrame[mani_?ManifoldQ]^=True;
SlotsOfTensor[PDFrame[mani_?ManifoldQ]]^:={-Tangent@mani};
PDFrame/:GradeOfTensor[PDFrame[mani_?ManifoldQ],CircleTimes]=1;
SymmetryGroupOfTensor[PDFrame[mani_?ManifoldQ]]^=StrongGenSet[{},GenSet[]];
DefInfo[PDFrame[mani_?ManifoldQ]]^={"General frame",""};
DependenciesOfTensor[PDFrame[mani_?ManifoldQ]]^:={mani};
HostsOf[PDFrame[mani_?ManifoldQ]]^={};
TensorID[PDFrame[mani_?ManifoldQ]]^={};
PrintAs[PDFrame[mani_?ManifoldQ]]^="\!\(\*FractionBox[\(\[PartialD]\),\(\[PartialD]x\)]\)";
(* ::Input::Initialization:: *)
(* xTensions *)
xTension["xTerior`",DefChart,"End"]:=setdiffs;
setdiffs[chartname_,__]:=Thread[ComponentValue[dx[ManifoldOfChart@chartname][{#,chartname}]&/@CNumbersOf@chartname,Diff/@ScalarsOfChart@chartname]];
(* ::Input::Initialization:: *)
xTension["xTerior`",DefChart,"End"]:=defFreeAlgebraChart;
defFreeAlgebraChart[basis_,__]:=With[{scalars=ScalarsOfChart[basis],numbers=CNumbersOf@basis,mani=ManifoldOfChart@basis},
(* Define the algebra elements forming the basis of the free algebra *) MapThread[DefTensor[GiveSymbol[basis,Abs@#1][],mani,PrintAs->ColorString["\!\(\*FractionBox[\(\[PartialD]\), \(\[PartialD]"<>PrintAs[Evaluate@(Head@#2)]<>"\)]\)",BasisColor@basis],GradeOfTensor->{CircleTimes->1},Master->basis]&,{numbers,scalars}];
(* Assign values *)
Thread[ComponentValue[dx[ManifoldOfChart@basis][{#,basis}]&/@CNumbersOf@basis,Diff/@ScalarsOfChart@basis]];
Thread[ComponentValue[PDFrame[mani][{#,-basis}]&/@numbers,GiveSymbol[basis,#][]&/@numbers]]
]
(* ::Input::Initialization:: *)
xTension["xTerior`",DefBasis,"End"]:=defFreeAlgebraBasis;
defFreeAlgebraBasis[basis_,__]:=With[{numbers=CNumbersOf@basis,
mani=BaseOfVBundle@VBundleOfBasis@basis},
If[Not@ChartQ@basis,
(* Define the algebra elements forming the basis of the free algebra *)
DefTensor[GiveSymbol[basis,Abs@#][],mani,GradeOfTensor->{CircleTimes->1},Master->basis]&/@numbers;
(* Assign values *)
Thread[ComponentValue[eFrame[mani][{#,-basis}]&/@numbers,GiveSymbol[basis,#][]&/@numbers]]
]
]
(* ::Input::Initialization:: *)
DefInertHead[Hodge[metric_],
LinearQ->True,
ContractThrough->{delta},
DefInfo->Null
]
(* ::Input::Initialization:: *)
Hodge/:PrintAs@Hodge[metric_]:=If[Head[metric]===CTensor,"*","\!\(\*SubscriptBox[\(*\), \("<>PrintAs[metric]<>"\)]\)"];
(* ::Input::Initialization:: *)
Hodge[metric_][expr_List]:=Hodge[metric][#]&/@expr;
Hodge[metric_][expr_Equal]:=Hodge[metric][#]&/@expr;
(* ::Input::Initialization:: *)
Hodge[metric_][CTensor[array_,bases_List,weight_][inds__]]:=CTensor[Hodge[metric][array],bases,weight][inds];
(* ::Input::Initialization:: *)
Hodge[metric_][x_ y_]:=x Hodge[metric][y]/;Grade[x,Wedge]===0
(* ::Input::Initialization:: *)
DimOfMetric[metric_]:=DimOfVBundle[VBundleOfMetric[metric]]
(* ::Input::Initialization:: *)
Hodge/:Grade[Hodge[metric_][expr_],Wedge]:=DimOfMetric[metric]-Grade[expr,Wedge]
(* ::Input::Initialization:: *)
Hodge[metric_]@Hodge[metric_][expr_]:=(-1)^(Grade[expr,Wedge](DimOfMetric[metric]-1)+SignatureOfMetric[metric][[2]])expr
(* ::Input::Initialization:: *)
(* Expand dual of differentials of coordinate elements *)
ExpandHodgeDual[expr_,dx[mani_?ManifoldQ],met_]:=ExpandHodgeDual1[(expr/.Reverse/@Flatten[List@@TensorValues@dx[mani]]),dx[mani],met];
(* Expand of the wedge product of canonical 1-forms *)
ExpandHodgeDual[expr_,(coframe:(Coframe|dx))[mani_?ManifoldQ],met_]:=ExpandHodgeDual1[expr,coframe[mani],met];
(* ::Input::Initialization:: *)
ExpandHodgeDual1[expr_,(coframe:(Coframe|dx))[mani_?ManifoldQ],met_]:=
expr/.{HoldPattern[Hodge[met][form:Wedge[coframe[mani][_]..]]|form:Hodge[met][coframe[mani][_]]]:>With[{dim=DimOfMetric[met],n=Length[form],inds=Sequence@@@List@@form},
With[{dummies=DummyIn/@ConstantArray[VBundleOfMetric[met],dim-n]},
1/(dim-n)!epsilon[met]@@Join[inds,ChangeIndex/@dummies]Wedge@@(coframe[mani]/@dummies)
]
],HoldPattern[Hodge[met][form_]]:>With[{dim=DimOfMetric[met]},
With[{dummies=DummyIn/@ConstantArray[VBundleOfMetric[met],dim]},
form/(dim)!epsilon[met]@@(ChangeIndex/@dummies)Wedge@@(coframe[mani]/@dummies)
]
]/;(Deg[form]===0)};
(* ::Input::Initialization:: *)
ExpandHodgeDual1[expr_,Coframe,met_]:=Fold[ExpandHodgeDual1[#1,Coframe[#2],met]&,expr,$Manifolds];
(* ::Input::Initialization:: *)
ExpandHodgeDual1[expr_,dx,met_]:=Fold[ExpandHodgeDual1[#1,dx[#2],met]&,expr,$Manifolds];
(* ::Input::Initialization:: *)
DefInertHead[Codiff[metric_],
LinearQ->True,
ContractThrough->delta,
DefInfo->Null
];
(* ::Input::Initialization:: *)
Codiff/:PrintAs@Codiff[metric_]:=If[Head@metric===CTensor,"\[Delta]","\!\(\*SubscriptBox[\(\[Delta]\), \("<>PrintAs[metric]<>"\)]\)"];
(* ::Input::Initialization:: *)
Codiff/:Grade[Codiff[metric_][expr_,___],Wedge]:=-1+Grade[expr,Wedge]
(* ::Input::Initialization:: *)
Codiff/:MakeBoxes[Codiff[metric_][form_,PD?CovDQ],StandardForm]:=xAct`xTensor`Private`interpretbox[Codiff[metric][form,PD],RowBox[{PrintAs[Codiff[metric]],"[",MakeBoxes[form,StandardForm],"]"}]];
Codiff/:MakeBoxes[Codiff[metric_][form_,cd_?CovDQ],StandardForm]:=xAct`xTensor`Private`interpretbox[Codiff[metric][form,cd],RowBox[{SuperscriptBox[PrintAs[Codiff[metric]],Last@SymbolOfCovD[cd]],"[",MakeBoxes[form,StandardForm],"]"}]];
(* ::Input::Initialization:: *)
HoldPattern[Codiff[met_][expr_]]:=Codiff[met][expr,PD];
(* ::Input::Initialization:: *)
CodiffToDiff[expr_]:=expr//.Codiff[met_][expr1_,covd_?CovDQ]:>(-1)^(DimOfMetric[met]Grade[expr1,Wedge]+DimOfMetric[met]+SignatureOfMetric[met][[2]])Hodge[met]@Diff[Hodge[met]@expr1,covd]
(* ::Input::Initialization:: *)
Codiff[metric_][Codiff[metric_][expr_,PD]]:=0
(* ::Input::Initialization:: *)
Codiff[_Basis,covd_?CovDQ]:=0;
(* ::Input::Initialization:: *)
Codiff@expr_List:=Codiff/@expr;
Codiff@expr_Equal:=Codiff/@expr;
(* ::Input::Initialization:: *)
FindPotential[expr_Plus,point_List,chart_?ChartQ,options:OptionsPattern[Integrate]]:=FindPotential[#,point,chart,options]&/@expr;
FindPotential[expr_Times,point_List,chart_?ChartQ,options:OptionsPattern[Integrate]]:=FindPotential[Expand@expr,point,chart,options];
(* ::Input::Initialization:: *)
(*Simplest cases for grade 1 forms *)
FindPotential[expr_Diff,point_List,chart_?ChartQ,options:OptionsPattern[Integrate]]:=Part[expr,1];
FindPotential[factor_ expr_Diff,point_List,chart_?ChartQ,options:OptionsPattern[Integrate]]:=Integrate1[(factor/.Thread[Rule[ScalarsOfChart@chart,Times[#,t]&/@(ScalarsOfChart@chart-point)+point]]) (Part[expr,1]-Part[point,First@Flatten@Position[ScalarsOfChart@chart,Part[expr,1]]]),{t,0,1},options];
(* Do the actual integration *)
Integrate1/:HoldPattern@Plus[var__Integrate1]:=Integrate[Plus@@First/@{var},{t,0,1}];
(* ::Input::Initialization:: *)
(* Poincare Lemma for higher degree forms *)
FindPotential[factor_. expr_Wedge,point_List,chart_?ChartQ,options:OptionsPattern[Integrate]]:=Integrate[(factor/.Thread[Rule[ScalarsOfChart@chart,Times[#,t]&/@(ScalarsOfChart@chart-point)+point]]) Sum[(-1)^(i-1)t^(Deg@expr-1) (Part[expr,i,1]-Part[point,First@Flatten@Position[ScalarsOfChart@chart,Part[expr,i,1]]])Delete[expr,{i}],{i,1,Length[expr]}],{t,0,1},options];
(* ::Input::Initialization:: *)
FormIntegrate::dim="Degree of form `1` is incompatible with dimension of manifold `2`.";
(* ::Input::Initialization:: *)
InertHeadQ[FormIntegrate]^:=True;
LinearQ[FormIntegrate]^:=True;
FormIntegrate[expr_Plus,man_?ManifoldQ]:=FormIntegrate[#,man]&/@expr;
FormIntegrate[form_,EmptyManifold]:=0;
FormIntegrate[c_?ConstantQ,man_?ManifoldQ]:=c/;DimOfManifold[man]==0;
FormIntegrate[form_,man_?ManifoldQ]:=If[
form===0,0,
Throw[Message[FormIntegrate::dim,form,man]];$Failed
]/;Deg[form]=!=DimOfManifold[man];
ToCanonical[FormIntegrate[form_,man_],opts___]^:=FormIntegrate[ToCanonical[form,opts],man];
FormIntegrate/:Grade[FormIntegrate[form_,man_],Wedge]:=0/;Deg[form]===DimOfManifold[man];
(* ::Input::Initialization:: *)
(* Formatting. Do not remove the ugly ?InertHeadQ check here. It would break typesetting *)
FormIntegrate/:MakeBoxes[FormIntegrate?InertHeadQ[form_,man_],StandardForm]:=RowBox[{SubscriptBox["\[Integral]",MakeBoxes[man,StandardForm]],MakeBoxes[form,StandardForm]}];
(* This doesn't work *)
MakeExpression[RowBox[{SubscriptBox["\[Integral]",man_],form_}],StandardForm]:=FormIntegrate[MakeExpression[form,StandardForm],MakeExpression[man,StandardForm]];
(* ::Input::Initialization:: *)
UseStokes[expr_]:=expr/.HoldPattern[FormIntegrate[Diff[form_,PD],man_]]:>FormIntegrate[form,ManifoldBoundary[man]];
UseStokes[expr_,man_?ManifoldQ]:=expr/.HoldPattern[FormIntegrate[Diff[form_,PD],man]]:>FormIntegrate[form,ManifoldBoundary[man]];
UseStokes[expr_,form_]:=expr/.HoldPattern[FormIntegrate[form,ManifoldBoundary[man_]]]:>FormIntegrate[Diff[form],man];
(* ::Input::Initialization:: *)
(* xTensions *)
(* Actual definition of the Koszul operator *)
xTension["xTerior`",DefCovD,"End"]:=defKoszulCovD;
(* Properties of the Koszul operator when acting on the elements of a chart *)
xTension["xCoba`",DefChart,"End"]:=setKoszulValue;
(* ::Input::Initialization:: *)
defKoszulCovD[covd_?CovDQ[_],__]:=With[{covdsymbol=GiveSymbol[Koszul,covd],covdsymbolf=GiveSymbol[CovD,covd]},
xAct`xTerior`Private`DefGradedDerivation[covdsymbol[v_],CircleTimes,0,PrintAs->Last@SymbolOfCovD[covd],Master->covd];
DefInertHead[covdsymbolf,PrintAs->Last@SymbolOfCovD[covd],LinearQ->True,Master->covd];
HoldPattern[covdsymbol[v_][expr_?ConstantQ]]:=0;
HoldPattern[covdsymbol[factor_ v_][expr_]]:=factor covdsymbol[v][expr]/;Grade[factor,CircleTimes]===0;
HoldPattern[covdsymbol[v_][expr1_ expr2_]]:=expr2 covdsymbol[v][expr1]+expr1 covdsymbol[v][expr2];
HoldPattern[covdsymbolf[expr_?ConstantQ]]:=0;
HoldPattern[covdsymbolf[expr_]]:=Diff[expr]/;Grade[expr,CircleTimes]===0;
HoldPattern[covdsymbolf[expr1_ expr2_]]:=CircleTimes[covdsymbolf[expr1],expr2]+CircleTimes[covdsymbolf[expr2],expr1];
CircleTimes/:HoldPattern@Grade[covdsymbolf[expr_],CircleTimes]:=Grade[expr,CircleTimes]+1;
Wedge/:HoldPattern[Grade[covdsymbolf[expr_],Wedge]]:=Grade[expr,Wedge]+1;
CircleTimes/:HoldPattern[Grade[covdsymbolf[expr_],CircleTimes]]:=Grade[expr,CircleTimes]+1;
HoldPattern[covd[{a_?NumberQ,basis_}]@expr_]:=
Which[
ChartQ[basis]&&Grade[expr,CircleTimes]>=1,
covdsymbol[PDFrame[ManifoldOfCovD@covd][{a,basis}]][expr],
BasisQ[basis]&&Grade[expr,CircleTimes]>=1,
covdsymbol[eFrame[ManifoldOfCovD@covd][{a,basis}]][expr],
True,
$Failed
];
HoldPattern[covd[{a_?NumberQ,-basis_}]@expr_]:=
Which[
ChartQ[basis]&&Grade[expr,CircleTimes]>=1,
covdsymbol[PDFrame[ManifoldOfCovD@covd][{a,-basis}]][expr],
BasisQ[basis]&&Grade[expr,CircleTimes]>=1,
covdsymbol[eFrame[ManifoldOfCovD@covd][{a,-basis}]][expr],
True,
$Failed
]
]
(* ::Input::Initialization:: *)
setKoszulValue[chart_?ChartQ,__]:=
With[{covd=PDOfBasis[chart]},
With[{sym0=GiveSymbol[Koszul,covd],sym1=GiveSymbol[PD,chart],mani=ManifoldOfChart[chart]},
Outer[Set[sym0[PDFrame[mani][{#1,-chart}]]@Part[ScalarsOfChart[chart],#2],sym1[{#1,-chart}][Part[ScalarsOfChart[chart],#2]]]&,CNumbersOf@chart,Range[1,Length@ScalarsOfChart@chart]];
Outer[Set[sym0[GiveSymbol[chart,#1][]]@Part[ScalarsOfChart[chart],#2],sym1[{#1,-chart}][Part[ScalarsOfChart[chart],#2]]]&,CNumbersOf@chart,Range[1,Length@ScalarsOfChart@chart]]
]
]
(* ::Input::Initialization:: *)
ExpandKoszul[expr_,covd1_?CovDQ,covd2_?CovDQ]:=expr/.{GiveSymbol[Koszul,covd1][eFrame[mani_?ManifoldQ][a_]][eFrame[mani_?ManifoldQ][b_]]:>
Module[{c=DummyIn[Tangent[mani]]},Christoffel[covd1,covd2][c,a,b]eFrame[mani][-c]],GiveSymbol[Koszul,covd1][eFrame[mani_?ManifoldQ][a_]][Coframe[mani_?ManifoldQ][b_]]:>Module[{c=DummyIn[Tangent[mani]]},-Christoffel[covd1,covd2][b,a,-c]Coframe[mani][c]],GiveSymbol[Koszul,covd1][PDFrame[mani_?ManifoldQ][a_]][PDFrame[mani_?ManifoldQ][b_]]:>
Module[{c=DummyIn[Tangent[mani]]},Christoffel[covd1,covd2][c,a,b]PDFrame[mani][-c]],GiveSymbol[Koszul,covd1][PDFrame[mani_?ManifoldQ][a_]][dx[mani_?ManifoldQ][b_]]:>Module[{c=DummyIn[Tangent[mani]]},-Christoffel[covd1,covd2][b,a,-c]dx[mani][c]]};
(* ::Input::Initialization:: *)
ExpandCovD[expr_,covd_?CovDQ,chart_?ChartQ]:=
With[{covdf=GiveSymbol[CovD,covd],M=ManifoldOfChart[chart],covdk=GiveSymbol[Koszul,covd]},
(expr/.HoldPattern[covdf[expr1_]]:>Plus@@(dx[M][{#,chart}]\[CircleTimes]covdk[PDFrame[M][{#,-chart}]][expr1]&/@CNumbersOf@chart)/;Grade[expr1,CircleTimes]===1)
]
(* ::Input::Initialization:: *)
xTensorQ[ConnectionForm[cd_?CovDQ,_]]^=True;
SlotsOfTensor[ConnectionForm[_,vb_?VBundleQ]]^:={vb,-vb};
ConnectionForm/:GradeOfTensor[ConnectionForm[_,_],Wedge]=1;
SymmetryGroupOfTensor[ConnectionForm[_,_]]^=StrongGenSet[{},GenSet[]];
Dagger[ConnectionForm[cd1_,vb_]]^:=ConnectionForm[cd1,Dagger@vb];
DefInfo[ConnectionForm[_,_]]^={"nonsymmetric Connection 1-form",""};
DependenciesOfTensor[ConnectionForm[cd1_,_]]^:=Union@@DependenciesOfCovD/@{cd1};
HostsOf[ConnectionForm[cd1_,vb_]]^:=Join[{cd1},Union@@HostsOf/@{cd1,vb}];(* Should we put Union@@HostsOf/@{cd1,vb} here? Yes but we need to add cd1 itself *)
TensorID[ConnectionForm[_,_]]^={};
PrintAs[ConnectionForm]^="A";
PrintAs[ConnectionForm[cd1_,_]]^:=PrintAs[ConnectionForm]<>"["<>Last@SymbolOfCovD[cd1]<>"]";
PrintAs[ConnectionForm[PD,_]]^:=PrintAs[ConnectionForm];
(* ::Input::Initialization:: *)
xTensorQ[ChristoffelForm[cd1_?CovDQ]]^=True;
SlotsOfTensor[ChristoffelForm[cd1_?CovDQ]]^:={Tangent@ManifoldOfCovD@cd1,-Tangent@ManifoldOfCovD@cd1};
ChristoffelForm/:GradeOfTensor[ChristoffelForm[_],Wedge]=1;
SymmetryGroupOfTensor[ChristoffelForm[_]]^=StrongGenSet[{},GenSet[]];
Dagger[ChristoffelForm[cd1_]]^:=ChristoffelForm[cd1];
DefInfo[ChristoffelForm[_]]^={"nonsymmetric frame bundle Connection 1-form",""};
DependenciesOfTensor[ChristoffelForm[cd1_]]^:=Union@@DependenciesOfCovD/@{cd1};
HostsOf[ChristoffelForm[cd1_]]^:=Join[{cd1},Union@@HostsOf/@{cd1}];(* Should we put Union@@HostsOf/@{cd1,cd2,vb} here? Yes, but addint also cd1 *)
TensorID[ChristoffelForm[_]]^={};
PrintAs[ChristoffelForm]^="\[CapitalGamma]";
(PrintAs[ChristoffelForm[cd1_]]/;Head@cd1=!=CCovD)^:=PrintAs[ChristoffelForm]<>"["<>Last@SymbolOfCovD[cd1]<>"]";
PrintAs[ChristoffelForm[PD]]^:=PrintAs[ChristoffelForm];
(* ::Input::Initialization:: *)
ChristoffelForm[exr_CCovD]:=Head@Module[{ind=DummyIn@VBundleOfBasis[-First@Part[Last@exr,2]],a1,a2},
{a1,a2}=GetIndicesOfVBundle[VBundleOfBasis[-First@Part[Last@exr,2]],2];
Part[exr,2][a1,-ind,-a2] ToCTensor[Coframe[BaseOfVBundle@VBundleOfBasis[-First@Part[Part[exr,3],2]]],{-First@Part[Part[exr,3],2]}][ind]
];
(* ::Input::Initialization:: *)
ConnectionForm[cd1_,vb_]:=ChristoffelForm[cd1]/;(Tangent@ManifoldOfCovD@cd1===vb);
ChristoffelForm[cd_,tangentbundle_]:=ChristoffelForm[cd];
(* ::Input::Initialization:: *)
ConnectionForm[PD,vb_]:=Zero;
ChristoffelForm[PD]:=Zero;
(* ::Input::Initialization:: *)
ConnectionFormToTensor[expr_,covd_,frame:(Coframe|dx)]:=expr/.{ChristoffelForm[cd1_][ind1_,ind2_]:>Module[{a=DummyIn@First@VBundlesOfCovD@covd,i1,i2},
i1=NewIndexIn[VBundleOfIndex[ind1]];
i2=NewIndexIn[VBundleOfIndex[ind2]];
If[xTensorQ@GiveSymbol[Christoffel,cd1,covd]===False,DefTensor[GiveSymbol[Christoffel,cd1,covd][i1,-a,i2],ManifoldOfCovD@covd]];
GiveSymbol[Christoffel,cd1,covd][ind1,-a,ind2]frame[ManifoldOfCovD@covd][a]]/;covd=!=PD,ConnectionForm[cd1_,vbundle_][ind1_,ind2_]:>Module[{a=DummyIn@Tangent@BaseOfVBundle@vbundle,i1,i2},
i1=NewIndexIn[VBundleOfIndex[ind1]];
i2=NewIndexIn[VBundleOfIndex[ind2]];
If[xTensorQ@GiveSymbol[AChristoffel,covd,cd1]===False,DefTensor[GiveSymbol[AChristoffel,covd,cd1][i1,-a,i2],BaseOfVBundle@vbundle]];
GiveSymbol[AChristoffel,covd,cd1][ind1,-a,ind2]frame[BaseOfVBundle@vbundle][a]]/;covd=!=PD};
(* ::Input::Initialization:: *)
ConnectionFormToTensor[expr_,PD,frame:(Coframe|dx)]:=expr/.{ChristoffelForm[cd1_][ind1_,ind2_]:>Module[{a=DummyIn@First@VBundlesOfCovD@cd1},
GiveSymbol[Christoffel,cd1][ind1,-a,ind2]frame[ManifoldOfCovD@cd1][a]],ConnectionForm[cd1_,_][ind1_,ind2_]:>Module[{a=DummyIn@First@VBundlesOfCovD@cd1},
GiveSymbol[AChristoffel,cd1][ind1,-a,ind2]frame[ManifoldOfCovD@cd1][a]]}
(* ::Input::Initialization:: *)
xTensorQ[CurvatureForm[_,_]]^=True;
SlotsOfTensor[CurvatureForm[_,vb_?VBundleQ]]^:={vb,-vb};
CurvatureForm/:GradeOfTensor[CurvatureForm[_,_],Wedge]=2;
SymmetryGroupOfTensor[CurvatureForm[_,_]]^=StrongGenSet[{},GenSet[]];
Dagger[CurvatureForm[cd_,vb_]]^:=CurvatureForm[cd,Dagger@vb];
DefInfo[CurvatureForm[_,_]]^={"Curvature 2-form",""};
DependenciesOfTensor[CurvatureForm[cd_,_]]^:=DependenciesOfCovD[cd];
HostsOf[CurvatureForm[cd_,vb_]]^:=Join[{cd},Union@@HostsOf/@{cd,vb}];(* Should we put Union@@HostsOf/@{cd,vb} here? Yes but we need to add cd itself *)
TensorID[CurvatureForm[_,_]]^={};
PrintAs[CurvatureForm]^="F";
PrintAs[CurvatureForm[cd_,_]]^:=PrintAs[CurvatureForm]<>"["<>Last@SymbolOfCovD[cd]<>"]";
(* ::Input::Initialization:: *)
xTensorQ[RiemannForm[_]]^=True;
SlotsOfTensor[RiemannForm[cd_?CovDQ]]^:={Tangent@ManifoldOfCovD@cd,-Tangent@ManifoldOfCovD@cd};
RiemannForm/:GradeOfTensor[RiemannForm[_],Wedge]=2;
SymmetryGroupOfTensor[RiemannForm[cd_?CovDQ]]^:=If[MetricOfCovD@cd=!=Null,
Antisymmetric[{1,2},Cycles],
StrongGenSet[{},GenSet[]]];
Dagger[RiemannForm[cd_]]^:=RiemannForm[cd];
DefInfo[RiemannForm[_]]^={"Curvature 2-form in the frame bundle",""};
DependenciesOfTensor[RiemannForm[cd_]]^:=DependenciesOfCovD[cd];
HostsOf[RiemannForm[cd_]]^:=Join[{cd},Union@@HostsOf/@{cd}];(* Should we put Union@@HostsOf/@{cd,vb} here? Yes but we need to add cd itself *)
TensorID[RiemannForm[_]]^={};
PrintAs[RiemannForm]^="R";
(PrintAs[RiemannForm[cd_]]/;Head@cd=!=CCovD)^:=PrintAs[RiemannForm]<>"["<>Last@SymbolOfCovD[cd]<>"]";
(* ::Input::Initialization:: *)
RiemannForm[exr_CCovD]:=If[Riemann[exr]=!=Zero,Head@Module[{ind1=DummyIn@VBundleOfBasis[-First@Part[Last@exr,2]],ind2=DummyIn@VBundleOfBasis[-First@Part[Last@exr,2]],a1,a2},
{a1,a2}=GetIndicesOfVBundle[VBundleOfBasis[-First@Part[Last@exr,2]],2];
Riemann[exr][-ind1,-ind2,-a1,a2] Wedge[ToCTensor[Coframe[BaseOfVBundle@VBundleOfBasis[-First@Part[Part[exr,3],2]]],{-First@Part[Part[exr,3],2]}][ind1],ToCTensor[Coframe[BaseOfVBundle@VBundleOfBasis[-First@Part[Part[exr,3],2]]],{-First@Part[Part[exr,3],2]}][ind2]]
],Zero
];
(* ::Input::Initialization:: *)
CurvatureForm[cd_?CovDQ,vbundle_]:=RiemannForm[cd]/;vbundle===Tangent@ManifoldOfCovD@cd;
RiemannForm[cd_,vbundle_]:=RiemannForm[cd];
(* ::Input::Initialization:: *)
CurvatureFormToTensor[expr_,frame:(Coframe|dx)]:=expr/.{HoldPattern@CurvatureForm[cd1_,vbundle1_?VBundleQ][inds__]:>Module[{a=DummyIn@First@VBundlesOfCovD@cd1,b=DummyIn@First@VBundlesOfCovD@cd1},
1/2GiveSymbol[FRiemann,cd1][-a,-b,Sequence@@Reverse@List@inds]Wedge[frame[ManifoldOfCovD@cd1][a],frame[ManifoldOfCovD@cd1][b]]],RiemannForm[cd1_][inds__]:>Module[{a=DummyIn@First@VBundlesOfCovD@cd1,b=DummyIn@First@VBundlesOfCovD@cd1},
-$RiemannSign 1/2GiveSymbol[Riemann,cd1][-a,-b,Sequence@@Reverse@List@inds]Wedge[frame[ManifoldOfCovD@cd1][a],frame[ManifoldOfCovD@cd1][b]]]}
(* ::Input::Initialization:: *)
xTensorQ[TorsionForm[_]]^=True;
SlotsOfTensor[TorsionForm[cd_]]^:={Tangent@ManifoldOfCovD@cd};
TorsionForm/:GradeOfTensor[TorsionForm[_],Wedge]=2;
SymmetryGroupOfTensor[TorsionForm[_]]^=StrongGenSet[{},GenSet[]];
Dagger[TorsionForm[cd_]]^:=TorsionForm[cd]
DefInfo[TorsionForm[_]]^={"Torsion 2-form",""};
DependenciesOfTensor[TorsionForm[cd_]]^:=DependenciesOfCovD[cd];
HostsOf[TorsionForm[cd_]]^:=HostsOf@cd;(* Should we put HostsOf@cd here? OK*)
TensorID[TorsionForm[_]]^={};
(* ::Input::Initialization:: *)
PrintAs[TorsionForm]^="\[GothicCapitalT]";
(PrintAs[TorsionForm[cd_]]/;Head@cd=!=CCovD)^:=PrintAs[TorsionForm]<>"["<>Last@SymbolOfCovD[cd]<>"]";