forked from ExpediaGroup/graphql-kotlin
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
197 lines (179 loc) · 6.69 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
import de.marcphilipp.gradle.nexus.NexusPublishExtension
import io.gitlab.arturbosch.detekt.detekt
import org.jetbrains.dokka.gradle.DokkaTask
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import java.time.Instant
description = "Libraries for running a GraphQL server in Kotlin"
extra["isReleaseVersion"] = !version.toString().endsWith("SNAPSHOT")
plugins {
id("org.jetbrains.kotlin.jvm")
id("org.jetbrains.dokka") apply false
id("org.jlleitschuh.gradle.ktlint")
id("io.gitlab.arturbosch.detekt")
jacoco
signing
`maven-publish`
id("de.marcphilipp.nexus-publish")
id("io.codearte.nexus-staging")
}
allprojects {
buildscript {
repositories {
mavenLocal()
jcenter()
mavenCentral()
}
}
repositories {
mavenLocal()
jcenter()
mavenCentral()
}
apply(plugin = "de.marcphilipp.nexus-publish")
configure<NexusPublishExtension> {
repositories {
sonatype {
username.set(System.getenv("SONATYPE_USERNAME"))
password.set(System.getenv("SONATYPE_PASSWORD"))
}
}
}
}
subprojects {
val kotlinVersion: String by project
val junitVersion: String by project
val mockkVersion: String by project
val detektVersion: String by project
val ktlintVersion: String by project
val jacocoVersion: String by project
val currentProject = this
apply(plugin = "kotlin")
apply(plugin = "io.gitlab.arturbosch.detekt")
apply(plugin = "org.jlleitschuh.gradle.ktlint")
apply(plugin = "jacoco")
apply(plugin = "java-library")
apply(plugin = "org.jetbrains.dokka")
apply(plugin = "maven-publish")
apply(plugin = "signing")
tasks.withType<KotlinCompile> {
kotlinOptions {
jvmTarget = "1.8"
freeCompilerArgs = listOf("-Xjsr305=strict")
}
}
tasks {
check {
dependsOn(jacocoTestCoverageVerification)
}
detekt {
toolVersion = detektVersion
config = files("${rootProject.projectDir}/detekt.yml")
}
ktlint {
version.set(ktlintVersion)
}
jacoco {
toolVersion = jacocoVersion
}
jar {
manifest {
attributes["Built-By"] = "Expedia Group"
attributes["Build-Jdk"] = "${System.getProperty("java.version")} (${System.getProperty("java.vendor")} ${System.getProperty("java.vm.version")})"
attributes["Build-Timestamp"] = Instant.now().toString()
attributes["Created-By"] = "Gradle ${gradle.gradleVersion}"
attributes["Implementation-Title"] = currentProject.name
attributes["Implementation-Version"] = project.version
}
}
test {
useJUnitPlatform()
finalizedBy(jacocoTestReport)
}
// published artifacts
val jarComponent = currentProject.components.getByName("java")
val sourcesJar by registering(Jar::class) {
archiveClassifier.set("sources")
from(sourceSets.main.get().allSource)
}
val dokka by getting(DokkaTask::class) {
outputFormat = "javadoc"
outputDirectory = "$buildDir/javadoc"
}
val javadocJar by registering(Jar::class) {
archiveClassifier.set("javadoc")
from("$buildDir/javadoc")
dependsOn(dokka.path)
}
publishing {
publications {
create<MavenPublication>("mavenJava") {
pom {
name.set("${currentProject.group}:${currentProject.name}")
url.set("https://github.com/ExpediaGroup/graphql-kotlin")
licenses {
license {
name.set("The Apache Software License, Version 2.0")
url.set("http://www.apache.org/licenses/LICENSE-2.0.txt")
}
}
organization {
name.set("Expedia Group")
name.set("https://www.expediagroup.com/")
}
developers {
developer {
name.set("Expedia Group Committers")
email.set("[email protected]")
organization.set("Expedia Group")
organizationUrl.set("https://www.expediagroup.com/")
}
}
scm {
connection.set("scm:git:git://github.com/ExpediaGroup/graphql-kotlin.git")
developerConnection.set("scm:git:git://github.com/ExpediaGroup/graphql-kotlin.git")
url.set("https://github.com/ExpediaGroup/graphql-kotlin")
}
// child projects need to be evaluated before their description can be read
val mavenPom = this
afterEvaluate {
mavenPom.description.set(currentProject.description)
}
}
from(jarComponent)
artifact(sourcesJar.get())
artifact(javadocJar.get())
}
}
}
signing {
setRequired {
(rootProject.extra["isReleaseVersion"] as Boolean) && gradle.taskGraph.hasTask("publish")
}
val signingKey: String? = System.getenv("GPG_SECRET")
val signingPassword: String? = System.getenv("GPG_PASSPHRASE")
useInMemoryPgpKeys(signingKey, signingPassword)
sign(publishing.publications["mavenJava"])
}
}
dependencies {
implementation("org.jetbrains.kotlin:kotlin-stdlib:$kotlinVersion")
testImplementation("org.jetbrains.kotlin:kotlin-test-junit5:$kotlinVersion")
testImplementation("org.junit.jupiter:junit-jupiter-api:$junitVersion")
testImplementation("org.junit.jupiter:junit-jupiter-engine:$junitVersion")
testImplementation("io.mockk:mockk:$mockkVersion")
}
}
tasks {
jar {
enabled = false
}
nexusStaging {
username = System.getenv("SONATYPE_USERNAME")
password = System.getenv("SONATYPE_PASSWORD")
packageGroup = rootProject.group.toString()
numberOfRetries = 60
delayBetweenRetriesInMillis = 5000
}
val publish by getting
publish.dependsOn(":initializeSonatypeStagingRepository")
}