-
Notifications
You must be signed in to change notification settings - Fork 3
/
elpygen.el
243 lines (209 loc) · 9.02 KB
/
elpygen.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
;;; elpygen.el --- Generate a Python function/method using a symbol under point -*- lexical-binding: t; -*-
;; Copyright (C) 2017 Vladimir Kazanov
;; Author: Vladimir Kazanov <[email protected]>
;; Version: 0.1.0
;; Package-Requires: ((emacs "25") (yasnippet "0.8.0"))
;; Keywords: Python, Languages, Tools
;; URL: https://github.com/vkazanov/elpygen
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License
;; as published by the Free Software Foundation; either version 3
;; of the License, or (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;;
;; `elpygen.el' uses the symbol name and it's arguments under point to
;; insert a method or a function stub into a suitable place. It also
;; makes sure the symbol is not already defined, and the requested
;; symbol is really a function/method call.
;;
;; To use the package just bind the main function to a suitable key:
;;
;; (define-key python-mode-map (kbd "C-c i") 'elpygen-implement).
;;
;;; Code:
(require 'yasnippet)
(require 'python)
(require 'rx)
(require 'subr-x)
(require 'thingatpt)
(require 'cl-lib)
(defvar elpygen-function-template "def ${1:`fun`}(${2:`args`}):
${0:pass}
"
"A Yasnippet template to be used for a function stub.")
(defvar elpygen-method-template "def ${1:`fun`}(${2:`(if (not (string-empty-p args)) (concat \"self, \" args) \"self\")`}):
${0:pass}
"
"A Yasnippet template to be used for a method stub.")
(defvar elpygen--varname-re (python-rx line-start symbol-name line-end))
(defvar elpygen--call-re (python-rx (optional "self" "\\.") symbol-name (* space) "("))
(defvar elpygen--class-re (python-rx line-start (* space) "class" (+ space) symbol-name))
;;;###autoload
(defun elpygen-implement ()
"Implement a function or a method using the symbol name and call arguments under the point."
(interactive)
(when (python-syntax-comment-or-string-p)
(user-error "Cannot extract symbols in comments/strings "))
(when (not (elpygen--looking-at-call-p))
(user-error "This doesn't look like a function/method call"))
(when (python-info-looking-at-beginning-of-defun)
(user-error "This is a function/method/class definition, not a call"))
(push-mark)
(if-let (name (elpygen--get-def-name))
(if (elpygen--symbol-method-p name)
(elpygen--implement-or-find-method (string-remove-prefix "self." name))
(elpygen--implement-or-find-function name))
(user-error "Failed to find a suitable symbol")))
(defun elpygen--looking-at-call-p ()
"Check if looking at a proper call."
(save-excursion
(with-syntax-table python-dotty-syntax-table
(and (thing-at-point 'symbol)
(beginning-of-thing 'symbol)
(looking-at-p elpygen--call-re)))))
(defun elpygen--symbol-method-p (symbol-name)
"Check if a symbol is a method call.
Argument SYMBOL-NAME the name of the symbol to check."
(string-prefix-p "self." symbol-name t))
(defun elpygen--find-function-definition (name)
"Find a top-level function definition or return nil.
Argument NAME the name of the symbol to check."
(save-excursion
(goto-char (point-min))
(when (re-search-forward (elpygen--make-defun-re name t) nil t)
(match-beginning 1))))
(defun elpygen--find-method-definition (name)
"Find a method definition in the current class or return nil.
Argument NAME the name of the symbol to check."
(save-excursion
(let (class-start class-end)
(while (and (not (elpygen--looking-at-class-definition))
(python-nav-backward-block)))
(setq class-start (point))
(python-nav-end-of-defun)
(setq class-end (point))
(goto-char class-start)
(when (re-search-forward (elpygen--make-defun-re name) class-end t)
(match-beginning 1)))))
(defun elpygen--make-defun-re (name &optional toplevel)
"Build a regex that match a function definition NAME.
Argument NAME is the name of the function to match.
Argument TOPLEVEL should be nil when nested definitions are ok, t
otherwise."
(macroexpand
`(python-rx
,@(if toplevel '(line-start "def" (+ space))
'(line-start (* space) "def" (+ space)))
(group-n 1 ,name) (* space) "(")))
(defun elpygen--looking-at-class-definition ()
"Check if looking at a class definition."
(save-excursion
(beginning-of-line 1)
(looking-at elpygen--class-re)))
(defun elpygen--implement-or-find-function (name)
"Find a top-level function definition or insert a function stub.
Argument NAME the name of the function to find or insert."
(if-let (pos (elpygen--find-function-definition name))
(progn
(goto-char pos)
(user-error "Function already implemented"))
(elpygen--implement-function name)))
(defun elpygen--implement-function (name)
"Find a top-level function definition or insert a function stub.
Argument NAME the name of the function to insert."
(let ((arglist (elpygen--get-arglist)))
(elpygen--prepare-function-insert-point)
(elpygen--insert-template elpygen-function-template
name
arglist)))
(defun elpygen--implement-or-find-method (name)
"Find a method in the current class or insert a method stub.
Argument NAME is the name of method to find or insert."
(unless (elpygen--within-method-p)
(user-error "Can only implement a method from within a method of a class"))
(if-let (pos (elpygen--find-method-definition name))
(progn
(goto-char pos)
(user-error "Method already implemented"))
(elpygen--implement-method name)))
(defun elpygen--implement-method (name)
"Insert a method stub into the current class.
Argument NAME is the name of method to insert."
(let ((arglist (elpygen--get-arglist)))
(elpygen--prepare-method-insert-point)
(elpygen--insert-template elpygen-method-template
name
arglist)))
(defun elpygen--within-method-p ()
"Check if the point is inside a method."
(when-let ((defun-info (python-info-current-defun))
(defun-info-parts (split-string defun-info "\\."))
(typed-defun-info (python-info-current-defun t)))
;; Should be a method (i.e. def) and should be within a class, i.e. defun info should contain at
;; least two parts, with the first capitalised. Should work most of the time.
(and (string-prefix-p "def" typed-defun-info)
(>= (length defun-info-parts) 2))))
(defun elpygen--insert-template (template name arglist)
"Insert a TEMPLATE into the current buffer.
Argument NAME is the name of the function/method to insert.
Argument ARGLIST is the argument list of the function/method."
(yas-expand-snippet template nil nil
`((fun ,name)
(args ,(elpygen--format-args arglist)))))
(defun elpygen--get-def-name ()
"Retrieve a symbol under the point."
(with-syntax-table python-dotty-syntax-table
(when-let (funname (thing-at-point 'symbol))
(substring-no-properties funname))))
(defun elpygen--get-arglist ()
"Retrieve the argument list of the symbol at point."
(save-excursion
(with-syntax-table python-dotty-syntax-table
(when (symbol-at-point)
(end-of-thing 'symbol)
(skip-chars-forward "[:blank:]")
(when (looking-at-p "(")
(when-let (sexp (thing-at-point 'sexp))
(elpygen--parse-arg-str sexp)))))))
(defun elpygen--parse-arg-str (arg-str)
"Make a list of arguments from ARG-STR."
(split-string (substring-no-properties arg-str 1 -1)
"," t split-string-default-separators))
(defun elpygen--format-args (arg-list)
"Build a string from the list of argument names.
Argument ARG-LIST is the list of argument names."
(let ((counter 0))
(cl-flet
((format-arg (arg)
(if (string-match-p elpygen--varname-re arg)
arg
(cl-incf counter)
(concat "arg" (number-to-string counter)))))
(string-join (mapcar #'format-arg arg-list) ", "))))
(defun elpygen--prepare-function-insert-point ()
"Move the point to a place suitable for function insertion."
(while (and
(> (current-indentation) 0)
(python-nav-backward-block)))
(python-nav-end-of-block)
(forward-line)
(newline 2))
(defun elpygen--prepare-method-insert-point ()
"Move the point to a place suitable for method insertion."
(let (target-indent)
(save-excursion
(while (and
(not (python-info-looking-at-beginning-of-defun))
(python-nav-backward-block)))
(setq target-indent (current-indentation)))
(python-nav-end-of-defun)
(newline 1)
(indent-to target-indent)))
(provide 'elpygen)
;;; elpygen.el ends here