-
Notifications
You must be signed in to change notification settings - Fork 1
/
sous_vide_wifi.ino
650 lines (553 loc) · 15.7 KB
/
sous_vide_wifi.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
#include <PID_v1.h>
#include <PID_AutoTune_v0.h>
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#include <EEPROM.h>
#include <Ticker.h>
#include "settings.h"
ESP8266WebServer server(80);
int offset = 0;
// Heater parameters
#define SLOW_COOKER_DIGITAL // Uncomment if you have a digital slow cooker
#ifdef SLOW_COOKER_DIGITAL
#define MINIMUM_ONTIME 500
#else
#define MINIMUM_ONTIME 0
#endif
// Parameters for the temperature pins
// On ESP8266, I believe bus MUST be set to 2 (correct me if I'm wrong!)
#define ONE_WIRE_BUS 2
#define ONE_WIRE_PWR 14
#define ONE_WIRE_GND 12
// Output Relay
#define RelayPin 16
// Setup a oneWire instance to communicate with any OneWire devices (not just Maxim/Dallas temperature ICs)
OneWire oneWire(ONE_WIRE_BUS);
// Pass our oneWire reference to Dallas Temperature.
DallasTemperature sensors(&oneWire);
// arrays to hold device address
DeviceAddress tempSensor;
// ************************************************
// PID Variables and constants
// ************************************************
//Define Variables we'll be connecting to
double Setpoint;
double Input;
double Output;
volatile long onTime = 0;
// pid tuning parameters
double Kp;
double Ki;
double Kd;
// EEPROM addresses for persisted data
const int SpAddress = 0;
const int KpAddress = 8;
const int KiAddress = 16;
const int KdAddress = 24;
//Specify the links and initial tuning parameters
PID myPID(&Input, &Output, &Setpoint, Kp, Ki, Kd, DIRECT);
// 10 second Time Proportional Output window
int WindowSize = 10000;
unsigned long windowStartTime;
// ************************************************
// Auto Tune Variables and constants
// ************************************************
byte ATuneModeRemember = 2;
// For more information on these parameters: http://playground.arduino.cc/Code/PIDAutotuneLibrary
double aTuneStep = 500; // Autotune in the range of +/- 500ms
double aTuneNoise = 1.0;
unsigned int aTuneLookBack = 20; // Peaks can be quite far apart, look back 20s
// Set a minimum autotune output, so the slow cooker does not turn off completely
double aTuneMinOutput = 10.0;
boolean tuning = false;
PID_ATune aTune(&Input, &Output);
// ************************************************
// States for state machine
// ************************************************
enum operatingState { OFF = 0, SETP, RUN};
operatingState opState = OFF;
// Use Ticker to handle timer
Ticker timer2;
Ticker timer_http;
void timer2_callback();
void timer_http_callback();
const int logInterval = 10000; // log every 10 seconds
long lastLogTime = 0;
// ************************************************
// HTML Setup
// ************************************************
const char DefaultHTMLStart[] PROGMEM =
"<html><head><title>Sous-Wifide</title>"
"<link rel=\"stylesheet\" href=\"https://maxcdn.bootstrapcdn.com/bootstrap/3.3.5/css/bootstrap.min.css\">"
"<link rel=\"stylesheet\" href=\"https://maxcdn.bootstrapcdn.com/bootstrap/3.3.5/css/bootstrap-theme.min.css\">"
"<script src=\"https://maxcdn.bootstrapcdn.com/bootstrap/3.3.5/js/bootstrap.min.js\"></script>"
"</head>"
"<body>";
const char DefaultHTMLEnd[] PROGMEM =
"</body></html>";
void LoadParameters();
void SaveParameters();
void handleRoot();
void handleSetTemperature();
void handleGetStatus();
void handleSetRun();
void handleSetAutotune();
void handleSetDefaultParameters();
void Off();
void Run();
void DoControl();
void DriveOutput();
double EEPROM_readDouble(int);
void EEPROM_writeDouble(int, double);
void FinishAutoTune();
void setup(void) {
//ESP.wdtDisable(); // used to debug, disable wachdog timer,
Serial.begin(115200); // full speed to monitor
Serial.print("Let's get cooking!\n");
// Initialize Relay Control:
pinMode(RelayPin, OUTPUT); // Output mode to drive relay
digitalWrite(RelayPin, LOW); // make sure it is off to start
// Set up wifi
WiFi.begin(SSID, PASS); // Connect to WiFi network
while (WiFi.status() != WL_CONNECTED) { // Wait for connection
delay(500);
Serial.print(".");
}
Serial.print("SSID: ");
Serial.println(SSID);
Serial.println("\n");
// Set up Ground & Power for the sensor from GPIO pins
pinMode(ONE_WIRE_GND, OUTPUT);
digitalWrite(ONE_WIRE_GND, LOW);
pinMode(ONE_WIRE_PWR, OUTPUT);
digitalWrite(ONE_WIRE_PWR, HIGH);
// Start up the DS18B20 One Wire Temperature Sensor
sensors.begin();
if (!sensors.getAddress(tempSensor, 0))
{
Serial.print(F("Sensor Error"));
}
sensors.setResolution(tempSensor, 12);
sensors.setWaitForConversion(false);
// Initialize the PID and related variables
LoadParameters();
myPID.SetTunings(Kp, Ki, Kd);
myPID.SetSampleTime(1000);
myPID.SetOutputLimits(0, WindowSize);
// Set up the webserver
//MDNS.begin(host);
//Serial.println("mDNS responder started");
server.on("/", handleRoot);
server.on("/set_temperature/", handleSetTemperature);
server.on("/get_status/", handleGetStatus);
server.on("/set_run/", handleSetRun);
server.on("/set_autotune/", handleSetAutotune);
server.on("/set_default_parameters/", handleSetDefaultParameters);
server.begin();
//MDNS.addService("http", "tcp", 80);
// Start the timers
//timer_http.attach(0.1, timer_http_callback);
timer2.attach(0.015, timer2_callback);
// Temporarily set this to be running all the time
myPID.SetMode(AUTOMATIC);
opState = RUN;
Setpoint = 50.0;
}
// ************************************************
// Main Control Loop
//
// All state changes pass through here
// ************************************************
void loop()
{
switch (opState)
{
case OFF:
Off();
break;
case RUN:
Run();
break;
}
delay(100); // Allow the ESP8266 to do other things
}
// ************************************************
// Initial State - press RIGHT to enter setpoint
// ************************************************
void Off()
{
myPID.SetMode(MANUAL);
digitalWrite(RelayPin, LOW); // make sure it is off
int keep_going = 1;
while (keep_going) {
// Check the webserver for updates
server.handleClient();
// Check to make sure we're still in off mode
if (opState != OFF) {
keep_going = 0;
}
delay(100);
}
// Prepare to transition to the RUN state
sensors.requestTemperatures(); // Start an asynchronous temperature reading
//turn the PID on
myPID.SetMode(AUTOMATIC);
windowStartTime = millis();
}
// ************************************************
// PID COntrol State
// SHIFT and RIGHT for autotune
// RIGHT - Setpoint
// LEFT - OFF
// ************************************************
void Run()
{
Serial.print("Run state");
SaveParameters();
myPID.SetTunings(Kp, Ki, Kd);
while (true)
{
// Check the webserver for updates
server.handleClient();
// Check to make sure we're still in run mode
if (opState != RUN) {
return;
}
DoControl();
// periodically log to serial port in csv format
if (millis() - lastLogTime > logInterval)
{
Serial.print(Input);
Serial.print(",");
Serial.println(Output);
Serial.print(",");
Serial.print(Setpoint);
Serial.print("\n");
lastLogTime = millis();
}
delay(100);
}
}
void timer2_callback() {
if (opState == OFF)
{
digitalWrite(RelayPin, LOW); // make sure relay is off
}
else
{
DriveOutput();
}
}
void LoadParameters()
{
// Load from EEPROM
EEPROM.begin(512); // On esp8266, we need to init EEPROM
Setpoint = EEPROM_readDouble(SpAddress);
Kp = EEPROM_readDouble(KpAddress);
Ki = EEPROM_readDouble(KiAddress);
Kd = EEPROM_readDouble(KdAddress);
// Use defaults if EEPROM values are invalid
if (isnan(Setpoint))
{
Setpoint = 60;
}
if (isnan(Kp))
{
Kp = 850;
}
if (isnan(Ki))
{
Ki = 0.5;
}
if (isnan(Kd))
{
Kd = 0.1;
}
Serial.print(Setpoint);
Serial.print("\n");
Serial.print(Kp);
Serial.print("\n");
Serial.print(Ki);
Serial.print("\n");
Serial.print(Kd);
Serial.print("\n");
EEPROM.end();
}
// ************************************************
// Save any parameter changes to EEPROM
// ************************************************
void SaveParameters()
{
EEPROM.begin(512); // On esp8266, we need to init EEPROM
if (Setpoint != EEPROM_readDouble(SpAddress))
{
EEPROM_writeDouble(SpAddress, Setpoint);
}
if (Kp != EEPROM_readDouble(KpAddress))
{
EEPROM_writeDouble(KpAddress, Kp);
}
if (Ki != EEPROM_readDouble(KiAddress))
{
EEPROM_writeDouble(KiAddress, Ki);
}
if (Kd != EEPROM_readDouble(KdAddress))
{
EEPROM_writeDouble(KdAddress, Kd);
}
EEPROM.commit(); // Another esp8266 thing
EEPROM.end();
}
// ************************************************
// Write floating point values to EEPROM
// ************************************************
void EEPROM_writeDouble(int address, double value)
{
byte* p = (byte*)(void*)&value;
for (int i = 0; i < sizeof(value); i++)
{
EEPROM.write(address++, *p++);
}
}
// ************************************************
// Read floating point values from EEPROM
// ************************************************
double EEPROM_readDouble(int address)
{
double value = 0.0;
byte* p = (byte*)(void*)&value;
for (int i = 0; i < sizeof(value); i++)
{
*p++ = EEPROM.read(address++);
}
return value;
}
// ************************************************
// Execute the control loop
// ************************************************
void DoControl()
{
// Read the input:
Input = sensors.getTempC(tempSensor);
sensors.requestTemperatures(); // prime the pump for the next one - but don't wait
if (tuning) // run the auto-tuner
{
if (aTune.Runtime()) // returns 'true' when done
{
FinishAutoTune();
}
}
else // Execute control algorithm
{
myPID.Compute();
}
// Time Proportional relay state is updated regularly via timer interrupt.
onTime = Output;
// If a digital slow cooker goes off for too long, it loses its settings
if (onTime < MINIMUM_ONTIME) {
onTime = MINIMUM_ONTIME;
}
}
// ************************************************
// Called by ISR every 15ms to drive the output
// ************************************************
void DriveOutput()
{
long now = millis();
// Set the output
// "on time" is proportional to the PID output
if (now - windowStartTime > WindowSize)
{ //time to shift the Relay Window
windowStartTime += WindowSize;
}
if ((onTime > 100) && (onTime > (now - windowStartTime)))
{
digitalWrite(RelayPin, HIGH);
}
else
{
digitalWrite(RelayPin, LOW);
}
}
// ************************************************
// Start the Auto-Tuning cycle
// ************************************************
void StartAutoTune()
{
// Remember the mode we were in
ATuneModeRemember = myPID.GetMode();
// Set up the auto-tune parameters
aTune.SetNoiseBand(aTuneNoise);
aTune.SetOutputStep(aTuneStep);
aTune.SetLookbackSec((int)aTuneLookBack);
aTune.SetControlType(1);
// Turn tuning mode on
tuning = true;
// We don't want Output to go below 0, so set the initial
// value of Output before we autotune
if (Output - aTuneStep < aTuneMinOutput) {
Output = aTuneStep + aTuneMinOutput;
}
// Don't let the auto tuner go beneath the minimum output either
if (Output - aTuneStep < double(MINIMUM_ONTIME)) {
Output = aTuneStep + double(MINIMUM_ONTIME);
}
}
// ************************************************
// Return to normal control
// ************************************************
void FinishAutoTune()
{
tuning = false;
// Extract the auto-tune calculated parameters
Kp = aTune.GetKp();
Ki = aTune.GetKi();
Kd = aTune.GetKd();
// Re-tune the PID and revert to normal control mode
myPID.SetTunings(Kp, Ki, Kd);
myPID.SetMode(ATuneModeRemember);
// Persist any changed parameters to EEPROM
SaveParameters();
}
void handleRoot() {
//String message(DefaultHTMLStart);
String message = "";
message += "<b>Welcome to Sous-Wifide!</b><br/><br/>";
// Give the status of the system
message += "Temperature: ";
message += Input;
message += "<br/>";
message += "Running: ";
if (opState == RUN) {
message += "true";
} else {
message += "false";
}
message += "<br/>";
message += "Auto-tuning: ";
if (tuning) {
message += "true";
} else {
message += "false";
}
message += "<br/>";
message += "Setpoint temperature: ";
message += Setpoint;
message += "<br/>";
message += "Kp: ";
message += Kp;
message += "<br/>";
message += "Ki: ";
message += Ki;
message += "<br/>";
message += "Kd: ";
message += Kd;
message += "<br/>";
// Debug info
message += "<br/><br/><br/>";
message += "millis: ";
message += millis();
message += "<br/>";
message += "WindowSize: ";
message += WindowSize;
message += "<br/>";
message += "windowStartTime: ";
message += windowStartTime;
message += "<br/>";
message += "Input: ";
message += Input;
message += "<br/>";
message += "Output: ";
message += Output;
message += "<br/>";
message += "onTime: ";
message += onTime;
message += "<br/>";
//message += String(DefaultHTMLEnd);
server.send(200, "text/html", message);
}
void handleSetTemperature() {
String message = "";//DefaultHTMLStart;
char new_setpoint[200];
server.arg("value").toCharArray(new_setpoint, 200);
Setpoint = double(atof(new_setpoint));
message += "Target Temperature: ";
message += Setpoint;
//message += DefaultHTMLEnd;
server.send(200, "text/html", message);
}
void handleGetStatus() {
String message = "{\"temperature\":";
message += Input;
message += ",\"output\":";
message += Output;
message += ",\"opstate\":";
message += opState;
message += ",\"autotune\":";
if (tuning) {
message += "true";
}else {
message += "false";
}
message += "}";
server.send(200, "application/json", message);
}
void handleSetRun() {
String value = server.arg("value");
String message = "";//DefaultHTMLStart;
if (value == "true") {
opState = RUN;
}else if (value == "false") {
opState = OFF;
}else {
value = "Invalid value given";
}
message += "Run: ";
message += value;
//message += DefaultHTMLEnd;
server.send(200, "text/html", message);
}
void handleSetAutotune() {
String value = server.arg("value");
String message = "";//DefaultHTMLStart;
if (value == "true") {
if (tuning){
message += "Autotune is already started. Please wait for it to complete.<br/>";
} else if (abs(Input - Setpoint) < 0.5) {
message += "Starting autotune.<br/>This may take some time, go enjoy a tea.<br/>";
StartAutoTune();
} else {
message += "Can't start autotune yet. Please wait until the current temperature is within 0.5C";
}
}else if (value == "false") {
message += "Ending autotune.<br/>WARNING: This may result in invalid parameters. For best operation, let autotune finish on its own<br/>";
FinishAutoTune(); // Not necessary to call this, autotune will turn itself off when it's done
}else {
message += "Invalid value given. Value must be true or false";
}
//message += DefaultHTMLEnd;
server.send(200, "text/html", message);
}
void resetDefaultParameters() {
Setpoint = 60;
// These are the Adafruit default parameters:
Kp = 850;
Ki = 0.5;
Kd = 0.1;
}
void handleSetDefaultParameters() {
String confirm = server.arg("confirm");
String message = "";//DefaultHTMLStart;
if (confirm == "true") {
resetDefaultParameters();
SaveParameters();
message += "Parameters reset to defaults<br/>";
}else {
message += "Please set confirm to true<br/>";
}
//message += DefaultHTMLEnd;
server.send(200, "text/html", message);
}