forked from HYCOM/HYCOM-src
-
Notifications
You must be signed in to change notification settings - Fork 0
/
mod_tsadvc.F90
2504 lines (2485 loc) · 85.4 KB
/
mod_tsadvc.F90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#if defined(ROW_LAND)
#define SEA_P .true.
#define SEA_U .true.
#define SEA_V .true.
#elif defined(ROW_ALLSEA)
#define SEA_P allip(j).or.ip(i,j).ne.0
#define SEA_U alliu(j).or.iu(i,j).ne.0
#define SEA_V alliv(j).or.iv(i,j).ne.0
#else
#define SEA_P ip(i,j).ne.0
#define SEA_U iu(i,j).ne.0
#define SEA_V iv(i,j).ne.0
#endif
module mod_tsadvc
use mod_xc ! HYCOM communication interface
use mod_pipe ! HYCOM debugging interface
implicit none
!
! --- module for tsadvc and related routines
!
private !! default is private
public :: tsadvc
!
integer, parameter, dimension (0:4) :: &
mbdy_advtyp = (/ 2, & !PCM
5, & !MPDATA
5, & !FCT2
0, & !N/A
5 /) !FCT4
!
logical, parameter :: lpipe_advem=.false. !extra checking (when pipe on)
logical, parameter :: lconserve =.false. !explicitly conserve the field
!
logical, save :: ldebug_tsdif !switch to debug diffusion - usually .false.
logical, save :: ldebug_advem !switch to debug advection - usually .false.
integer, save :: itests,jtests !local copy of itest,jtest
!
#if defined(RELO)
real, save, allocatable, dimension(:,:) :: &
#else
real, save, dimension(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy) :: &
#endif
fmx,fmn & ! local max,min
,flx,fly & ! fluxes
,fldlo & ! lo order solution
,fmxlo,fmnlo & ! local min
,fax,fay & ! fluxes
,rp,rm & ! FCT/MPDATA terms
,flxdiv & ! flux divergence
,tx1,ty1 & ! MPDATA terms
,fldao,fldan ! total field quantity (old/center, new)
#if defined(RELO)
real, save, allocatable, dimension(:,:) :: &
#else
real, save, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy):: &
#endif
uloc,vloc,hloc,dtloc,ucumdt,vcumdt,flxcum,flycum
#if defined(RELO)
logical, save, allocatable, dimension(:,:) :: &
#else
logical, save, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy):: &
#endif
lcalc
contains
subroutine advem(advtyp,fld,fldc,u,v,fco,fcn,posdef, &
scal,scali,dt2,btrmas)
implicit none
!
logical, intent(in) :: btrmas
integer, intent(in) :: advtyp
real, intent(in) :: posdef,dt2
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(inout) :: fld
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(in) :: fldc,u,v,fco,fcn,scal,scali
!
! --- wrapper for advection schemes
!
! --- a recent text on advection schemes is:
! --- D.R. Durran (1999): Numerical Methods for wave equations in
! --- geophysical fluid dynamics, Springer.
!
! --- advtyp= 0 for 1st order PCM (Donor Cell)
! --- advtyp= 1 for 2nd order MPDATA (old to new, as in 2.1.03)
! --- advtyp= 2 for 2nd order FCT (Leapfrog time step)
! --- advtyp= 4 for 4th order FCT (Leapfrog time step)
!
! --- time steps are "old", "center" and "new".
!
! --- fld - scalar field, at old time step on input but new on output
! --- fldc - scalar field, at center time step
! --- u,v - mass fluxes satisfying continuity equation (old to new)
! --- fco - thickness of the layer at old time step
! --- fcn - thickness of the layer at new time step
! --- posdef - offset for MPDATA to make the field positive
! --- scal - spatial increments (squared)
! --- scali - inverse of scal
! --- dt2 - temporal increment (from old to new, i.e. two time steps)
!
! on return, fld's valid halo will be 0 wide.
!
real offset
real*8 sumold,sumnew,sumcor
integer i,j
!
#if defined(RELO)
if (.not.allocated(fmx)) then
allocate( &
fmx(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fmn(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
flx(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fly(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fldlo(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fmxlo(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fmnlo(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fax(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fay(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
rp(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
rm(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
flxdiv(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
tx1(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
ty1(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fldao(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
fldan(1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy) )
call mem_stat_add( 16*(idm+2*nbdy)*(jdm+2*nbdy) )
fmx = r_init
fmn = r_init
flx = r_init
fly = r_init
fldlo = r_init
fmxlo = r_init
fmnlo = r_init
fax = r_init
fay = r_init
rp = r_init
rm = r_init
flxdiv = r_init
tx1 = r_init
ty1 = r_init
fldao = r_init
fldan = r_init
endif !.not.allocated
#endif
!
if (advtyp.eq.0) then
call advem_pcm( fld, u,v,fco,fcn, scal,scali,dt2)
elseif (advtyp.eq.1) then
call advem_mpdata(fld, u,v,fco,fcn,posdef,scal,scali,dt2)
elseif (advtyp.eq.2 .and. btrmas) then
call advem_fct2c( fld,fldc,u,v,fco,fcn, scal,scali,dt2)
elseif (advtyp.eq.2) then !.not.btrmas
call advem_fct2( fld,fldc,u,v,fco,fcn, scal,scali,dt2)
elseif (advtyp.eq.4) then
call advem_fct4( fld,fldc,u,v,fco,fcn, scal,scali,dt2)
else
if (mnproc.eq.1) then
write(lp,'(/ a,i4 /)') &
'error: advem called with advtyp =',advtyp
endif
call xcstop('advem')
stop 'advem'
endif
!
if (lconserve) then !usually .false.
!
! --- explicit conservation of tracer (should not be needed).
!
call xcsum(sumold, fldao,ipa)
call xcsum(sumnew, fldan,ipa)
!
if (sumnew.ne.0.0) then
offset = (sumold-sumnew)/sumnew
else
offset = 0.0
endif
!
!$OMP PARALLEL DO PRIVATE(j,i,offset) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1,jj
do i=1,ii
if (SEA_P) then
fld(i,j)=fld(i,j)*(1.0+offset)
!
!diag fldan(i,j) = fld(i,j)*fcn(i,j)*scal(i,j)
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(fld, ip,'ad:oset:fld ')
endif
!
!diag call xcsum(sumcor, fldan,ipa)
!diag if (mnproc.eq.1) then
!diag write(lp,'(a,1p4e16.8)') &
!diag 'advem: ',sumold,sumnew,sumcor,offset
!diag endif
endif !lconserve
return
end subroutine advem
subroutine advem_mpdata(fld,u,v,fco,fcn,posdef,scal,scali,dt2)
implicit none
!
real, intent(in) :: posdef,dt2
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(inout) :: fld
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(in) :: u,v,scal,scali,fco,fcn
!
! LeapFrog 2nd order MPDATA.
! combined monotone scheme, for details see section 3.3 (eqs. 34 to 37)
! in smolarkiewicz and clark, 1986, j.comput.phys.,67,no 2, p. 396-438
! and smolarkiewicz and grabowski, 1989, j.comput.phys. and recently
! P.K. Smolarkiewicz and L.J. Margolin (1998): MPDATA: A finite
! difference solver for geophysical flows, J.Comput.Phys. 140 459-480.
!
! time steps are "old", "center" and "new".
!
! fld - scalar field, must be >0, old input but new output
! u,v - mass fluxes satisfying continuity equation (old to new)
! fco - thickness of the layer at old time step
! fcn - thickness of the layer at new time step
! posdef - offset to make the field positive
! scal - spatial increments (squared)
! scali - inverse of scal
! dt2 - temporal increment (from old to new)
!
! on return, fld's valid halo will be 0 wide.
!
real, parameter :: onemu=9806.e-12 !very small layer thickness
!
real fcn2,fco2,flxdn,flxdp,flydn,flydp,q
integer i,j,l,ia,ib,ja,jb,mbdy_a,margin
!
mbdy_a = mbdy_advtyp(1) ! = 5
!
! --- compute low-order and part of antidiffusive fluxes
!
! --- rhs: u, v, fld+
! --- lhs: flx, fly, fmx, fmn
!
margin = mbdy_a - 1
!
!$OMP PARALLEL DO PRIVATE(j,i,q,jb,ja,ib,ia) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_U) then
tx1(i,j)=.5*abs(u(i,j))*(fld(i,j)-fld(i-1,j))
if (u(i,j).ge.0.0) then
q=fld(i-1,j)
else
q=fld(i ,j)
endif
flx(i,j)=u(i,j)*(q+posdef)
endif !iu
if (SEA_V) then
ty1(i,j)=.5*abs(v(i,j))*(fld(i,j)-fld(i,j-1))
if (v(i,j).ge.0.0) then
q=fld(i,j-1)
else
q=fld(i,j )
endif
fly(i,j)=v(i,j)*(q+posdef)
endif !iv
if (SEA_P) then
ia=ipim1(i,j) !i-1 if sea and i if land
ib=ipip1(i,j) !i+1 if sea and i if land
ja=ipjm1(i,j) !j-1 if sea and j if land
jb=ipjp1(i,j) !j+1 if sea and j if land
fmx(i,j)=max(fld(i,j),fld(ia,j),fld(ib,j), &
fld(i,ja),fld(i,jb))+posdef
fmn(i,j)=min(fld(i,j),fld(ia,j),fld(ib,j), &
fld(i,ja),fld(i,jb))+posdef
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
!
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(tx1, iu,'ad:11:tx1 ', &
ty1, iv,'ad:11:ty1 ')
call pipe_compare_sym2(flx, iu,'ad:11:flx ', &
fly, iv,'ad:11:fly ')
call pipe_compare_sym1(fmx, ip,'ad:11:fmx ')
call pipe_compare_sym1(fmn, ip,'ad:11:fmn ')
endif
!
! --- rhs: u, v, fld+
! --- lhs: flx, fly, fmx, fmn
!
margin = mbdy_a - 1
!
do j=1-margin,jj+margin
do l=1,isp(j) !ok
if (ifp(j,l).ge. 1-margin) then
flx(ifp(j,l) ,j)=0.0
endif
if (ilp(j,l).lt.ii+margin) then
flx(ilp(j,l)+1,j)=0.0
endif
enddo !l
enddo !j
!
do i=1-margin,ii+margin
do l=1,jsp(i) !ok
if (jfp(i,l).ge. 1-margin) then
fly(i,jfp(i,l) )=0.0
endif
if (jlp(i,l).lt.jj+margin) then
fly(i,jlp(i,l)+1)=0.0
endif
enddo !l
enddo !i
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad:22:flx ', &
fly, iv,'ad:33:fly ')
endif
!diag if (itests.gt.0 .and. jtests.gt.0) then
!diag i=itests
!diag j=jtests
!diag write (lp,'(a,2i5,f22.3/1pe39.2/0pf21.3,1pe9.2,0pf9.3, &
!diag 1pe9.2,0pf9.3/1pe39.2/0pf39.3)') &
!diag 'advem (1)',i+i0,j+j0, &
!diag fld(i-1,j),u(i,j),fld(i,j-1),v(i,j), &
!diag fld(i,j),v(i,j+1),fld(i,j+1),u(i+1,j),fld(i+1,j)
!diag endif
!
! --- rhs: flx+, fly+, fco, fmn, fmx, fcn
! --- lhs: fld
!
margin = mbdy_a - 2
!
!$OMP PARALLEL DO PRIVATE(j,i,q) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
!...........lo order Donor Cell step
flxdiv(i,j)=((flx(i+1,j)-flx(i,j))+ &
(fly(i,j+1)-fly(i,j)) )*dt2*scali(i,j)
q=(fld(i,j)+posdef)*(fco(i,j)+onemu)-flxdiv(i,j)
!max,min should only be active for very thin layers
fldlo(i,j)=max( fmn(i,j), min( fmx(i,j), &
q/(fcn(i,j)+onemu) ))
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(fldlo, ip,'ad:610:fldlo')
call pipe_compare_sym1(flxdiv, ip,'ad:610:flxdv')
endif
!
! --- finish computation of antidiffusive fluxes
!
! --- rhs: tx1, u, ty1, v, flxdiv+, fco+, fcn+
! --- lhs: flx, fly
!
margin = mbdy_a - 2
!
!$OMP PARALLEL DO PRIVATE(j,i,fcn2,fco2) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
fco2=0.0
fcn2=0.0
do i=1-margin,ii+margin
if (SEA_U) then
fco2=fco(i,j)+fco(i-1,j) ! inforce order on flx calc
fcn2=fcn(i,j)+fcn(i-1,j) ! inforce order on flx calc
flx(i,j)=tx1(i,j)-u(i,j)*(flxdiv(i,j)+flxdiv(i-1,j)) &
/((fco2+fcn2)+onemu)
endif !iu
if (SEA_V) then
fco2=fco(i,j)+fco(i,j-1) ! inforce order on fly calc
fcn2=fcn(i,j)+fcn(i,j-1) ! inforce order on fly calc
fly(i,j)=ty1(i,j)-v(i,j)*(flxdiv(i,j)+flxdiv(i,j-1)) &
/((fco2+fcn2)+onemu)
endif !iv
enddo !i
if (fco2*fcn2.eq.1.e30) flx(1-nbdy,j)=0.0 ! prevent removal of fc*2
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad: 8:flx ', &
fly, iv,'ad: 8:fly ')
endif
!
! --- limit antidiffusive fluxes
! --- rp and rm used to be called flp and fln
!
! --- rhs: fmx, fmn, fldlo, fcn, flx+, fly+
! --- lhs: rp, rm
!
margin = mbdy_a - 3
!
!$OMP PARALLEL DO PRIVATE(j,i,flxdn,flxdp,flydn,flydp) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
flxdp=min(0.0,flx(i+1,j))-max(0.0,flx(i,j))
flxdn=max(0.0,flx(i+1,j))-min(0.0,flx(i,j))
flydp=min(0.0,fly(i,j+1))-max(0.0,fly(i,j))
flydn=max(0.0,fly(i,j+1))-min(0.0,fly(i,j))
rp(i,j)=(fmx(i,j)-fldlo(i,j))*(fcn(i,j)*scal(i,j))/ &
((onemu-(flxdp+flydp))*dt2)
rm(i,j)=(fldlo(i,j)-fmn(i,j))*(fcn(i,j)*scal(i,j))/ &
((onemu+(flxdn+flydn))*dt2)
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(rp, ip,'ad:16:flp ')
call pipe_compare_sym1(rm, ip,'ad:16:fln ')
endif
!
! --- rhs: flx, fly, rp+, rm+
! --- lhs: flx, fly
!
margin = mbdy_a - 4
!
!$OMP PARALLEL DO PRIVATE(j,i) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_U) then
flx(i,j)=max(0.0,flx(i,j))*min(1.0,rp(i,j),rm(i-1,j)) &
+min(0.0,flx(i,j))*min(1.0,rp(i-1,j),rm(i,j))
endif !iu
if (SEA_V) then
fly(i,j)=max(0.0,fly(i,j))*min(1.0,rp(i,j),rm(i,j-1)) &
+min(0.0,fly(i,j))*min(1.0,rp(i,j-1),rm(i,j))
endif !iv
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad:18:flx ', &
fly, iv,'ad:18:fly ')
endif
!
!diag i=itests
!diag j=jtests
!diag write (lp,'(''advem (2)'',2i5,f22.3/1pe39.2/0pf21.3,1pe9.2,0pf9.3, &
!diag 1pe9.2,0pf9.3/1pe39.2/0pf39.3)') i,j,fldlo(i-1,j),u(i,j),fldlo(i,j-1), &
!diag v(i,j),fldlo(i,j),v(i,j+1),fldlo(i,j+1),u(i+1,j),fldlo(i+1,j)
!
! --- rhs: flx+, fly+, fldlo, fcn, fmx
! --- lhs: flxdiv, fld
!
margin = mbdy_a - 5
!
!$OMP PARALLEL DO PRIVATE(j,i) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
fldao(i,j) = fld(i,j)*fco(i,j)*scal(i,j)
!
!...........apply antidiffusive flux correction
flxdiv(i,j)=((flx(i+1,j)-flx(i,j))+ &
(fly(i,j+1)-fly(i,j)) )*dt2*scali(i,j)
!max,min should only be active for very thin layers
fld(i,j)=max( fmn(i,j), min( fmx(i,j), &
fldlo(i,j)-flxdiv(i,j)/(fcn(i,j)+onemu) ))
fld(i,j)=fld(i,j)-posdef
!
fldan(i,j) = fld(i,j)*fcn(i,j)*scal(i,j)
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(flxdiv, ip,'ad:620:flxdv')
call pipe_compare_sym1(fld, ip,'ad:1620:fld ')
endif
return
end subroutine advem_mpdata
subroutine advem_pcm(fld,u,v,fco,fcn,scal,scali,dt2)
implicit none
!
real, intent(in) :: dt2
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(inout) :: fld
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(in) :: u,v,scal,scali,fco,fcn
!
! Piecewise Constant Method (Donor Cell, Upwind)
! Over two time steps (may require half the normal time step for stability).
!
! time steps are "old", "center" and "new".
!
! fld - scalar field, need not be >0, old input but new output
! u,v - mass fluxes satisfying continuity equation (old to new)
! fco - thickness of the layer at old time step
! fcn - thickness of the layer at new time step
! scal - spatial increments (squared)
! scali - inverse of scal
! dt2 - temporal increment (from old to new)
!
! on return, fld's valid halo will be 0 wide.
!
real, parameter :: onemu=9806.e-12 !very small layer thickness
!
real q
integer i,j,l,ia,ib,ja,jb,mbdy_a,margin
!
! --- rhs: u, v, fld+
! --- lhs: flx, fly
!
mbdy_a = mbdy_advtyp(0) ! = 2
!
margin = mbdy_a - 1
!
!$OMP PARALLEL DO PRIVATE(j,i,q) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_U) then
if (u(i,j).ge.0.0) then
q=fld(i-1,j)
else
q=fld(i ,j)
endif
flx(i,j)=u(i,j)*q
endif !iu
if (SEA_V) then
if (v(i,j).ge.0.0) then
q=fld(i,j-1)
else
q=fld(i,j )
endif
fly(i,j)=v(i,j)*q
endif !iv
if (SEA_P) then
ia=ipim1(i,j) !i-1 if sea and i if land
ib=ipip1(i,j) !i+1 if sea and i if land
ja=ipjm1(i,j) !j-1 if sea and j if land
jb=ipjp1(i,j) !j+1 if sea and j if land
fmx(i,j)=max(fld(i,j),fld(ia,j),fld(ib,j), &
fld(i,ja),fld(i,jb))
fmn(i,j)=min(fld(i,j),fld(ia,j),fld(ib,j), &
fld(i,ja),fld(i,jb))
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
!
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad:11:flx ', &
fly, iv,'ad:11:fly ')
endif
!
do j=1-margin,jj+margin
do l=1,isp(j) !ok
if (ifp(j,l).ge. 1-margin) then
flx(ifp(j,l) ,j)=0.0
endif
if (ilp(j,l).lt.ii+margin) then
flx(ilp(j,l)+1,j)=0.0
endif
enddo !l
enddo !j
!
do i=1-margin,ii+margin
do l=1,jsp(i) !ok
if (jfp(i,l).ge. 1-margin) then
fly(i,jfp(i,l) )=0.0
endif
if (jlp(i,l).lt.jj+margin) then
fly(i,jlp(i,l)+1)=0.0
endif
enddo !l
enddo !i
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad:22:flx ', &
fly, iv,'ad:33:fly ')
endif
!diag if (itests.gt.0 .and. jtests.gt.0) then
!diag i=itests
!diag j=jtests
!diag write (lp,'(a,2i5,f22.3/1pe39.2/0pf21.3,1pe9.2,0pf9.3, &
!diag 1pe9.2,0pf9.3/1pe39.2/0pf39.3)') &
!diag 'advem (1)',i+i0,j+j0, &
!diag fld(i-1,j),u(i,j),fld(i,j-1),v(i,j), &
!diag fld(i,j),v(i,j+1),fld(i,j+1),u(i+1,j),fld(i+1,j)
!diag endif
!
! --- rhs: flx+, fly+, fld, fco, fcn
! --- lhs: flxdiv, fld
!
margin = mbdy_a - 2
!
!$OMP PARALLEL DO PRIVATE(j,i,q) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
fldao(i,j) = fld(i,j)*fco(i,j)*scal(i,j)
!
flxdiv(i,j)=((flx(i+1,j)-flx(i,j))+ &
(fly(i,j+1)-fly(i,j)) )*dt2*scali(i,j)
q=fld(i,j)*(fco(i,j)+onemu)-flxdiv(i,j)
!max,min should only be active for very thin layers
fld(i,j)=max( fmn(i,j), min( fmx(i,j), &
q/(fcn(i,j)+onemu) ))
!
fldan(i,j) = fld( i,j)*fcn(i,j)*scal(i,j)
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(fld, ip,'ad:610:fld ')
call pipe_compare_sym1(flxdiv, ip,'ad:610:flxdv')
endif
!
!diag i=itests
!diag j=jtests
!diag write (lp,'(''advem (2)'',2i5,f22.3/1pe39.2/0pf21.3,1pe9.2,0pf9.3, &
!diag 1pe9.2,0pf9.3/1pe39.2/0pf39.3)') i,j,fld(i-1,j),u(i,j),fld(i,j-1), &
!diag v(i,j),fld(i,j),v(i,j+1),fld(i,j+1),u(i+1,j),fld(i+1,j)
return
end subroutine advem_pcm
subroutine advem_fct2(fld,fldc,u,v,fco,fcn,scal,scali,dt2)
implicit none
!
real, intent(in) :: dt2
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(inout) :: fld
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(in) :: fldc,u,v,scal,scali,fco,fcn
!
! Leapfrog 2nd order FCT
! S.T. Zalesak (1979): Fully multidimensional flux-corrected
! transport algorithms for fluids, J.Comput.Phys. 31 335-362.
!
! time steps are "old", "center" and "new".
!
! fld - scalar field, need not be >0, old input but new output
! fldc - scalar field at center time step
! u,v - mass fluxes satisfying continuity equation (old to new)
! fco - thickness of the layer at old time step
! fcn - thickness of the layer at new time step
! scal - spatial increments (squared)
! scali - inverse of scal
! dt2 - temporal increment (from old to new)
!
! on return, fld's valid halo will be 0 wide.
!
real, parameter :: onemu=9806.e-12 !very small layer thickness
!
real flxdn,flxdp,flydn,flydp,q
integer i,j,l,ia,ib,ja,jb,mbdy_a,margin
!
real :: fhx, fhy, fqmax, fqmin, famax, famin
real :: qdt2, qp, qm, fact
mbdy_a = mbdy_advtyp(2) ! = 5
!
! --- compute low-order and part of antidiffusive fluxes
!
! --- rhs: u, v, fld+
! --- lhs: flx, fly, fmx, fmn
!
margin = mbdy_a - 1
!
!$OMP PARALLEL DO PRIVATE(j,i,q,jb,ja,ib,ia) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_U) then
if (u(i,j).ge.0.0) then
q=fld(i-1,j)
else
q=fld(i ,j)
endif
flx(i,j)=u(i,j)*q
endif !iu
if (SEA_V) then
if (v(i,j).ge.0.0) then
q=fld(i,j-1)
else
q=fld(i,j )
endif
fly(i,j)=v(i,j)*q
endif !iv
if (SEA_P) then
ia=ipim1(i,j) !i-1 if sea and i if land
ib=ipip1(i,j) !i+1 if sea and i if land
ja=ipjm1(i,j) !j-1 if sea and j if land
jb=ipjp1(i,j) !j+1 if sea and j if land
fmx(i,j)=max(fld(i,j),fld(ia,j),fld(ib,j), &
fld(i,ja),fld(i,jb))
fmn(i,j)=min(fld(i,j),fld(ia,j),fld(ib,j), &
fld(i,ja),fld(i,jb))
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
!
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
! call pipe_compare_sym2(tx1, iu,'ad:11:tx1 ',
! & ty1, iv,'ad:11:ty1 ')
! call pipe_compare_sym2(flx, iu,'ad:11:flx ',
! & fly, iv,'ad:11:fly ')
endif
!
if (ldebug_advem .and. itests.gt.0 .and. jtests.gt.0) then
i=itests
j=jtests
write (lp,'(a,2i5,3f10.5)') &
'advem: fld, rng ',i+i0,j+j0, &
fld(i,j),fmx(i,j),fmn(i,j)
endif
!
do j=1-margin,jj+margin
do l=1,isp(j) !ok
if (ifp(j,l).ge. 1-margin) then
flx(ifp(j,l) ,j)=0.0
endif
if (ilp(j,l).lt.ii+margin) then
flx(ilp(j,l)+1,j)=0.0
endif
enddo !l
enddo !j
!
do i=1-margin,ii+margin
do l=1,jsp(i) !ok
if (jfp(i,l).ge. 1-margin) then
fly(i,jfp(i,l) )=0.0
endif
if (jlp(i,l).lt.jj+margin) then
fly(i,jlp(i,l)+1)=0.0
endif
enddo !l
enddo !i
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad:22:flx ', &
fly, iv,'ad:33:fly ')
endif
!
!diag if (ldebug_advem .and. itests.gt.0 .and. jtests.gt.0) then
!diag i=itests
!diag j=jtests
!diag write (lp,'(a,2i5,f22.3/1pe39.2/0pf21.3,1pe9.2,0pf9.3, &
!diag 1pe9.2,0pf9.3/1pe39.2/0pf39.3)') &
!diag 'advem (1)',i+i0,j+j0, &
!diag fld(i-1,j),u(i,j),fld(i,j-1),v(i,j), &
!diag fld(i,j),v(i,j+1),fld(i,j+1),u(i+1,j),fld(i+1,j)
!diag endif
!
! --- rhs: flx+, fly+, fld, fmx, fmn, fco, fcn
! --- lhs: fldlo, fmxlo, fmnlo, flxdiv
!
margin = mbdy_a - 2
!
!$OMP PARALLEL DO PRIVATE(j,i,q) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
!...........lo order Donor Cell step
flxdiv(i,j)=((flx(i+1,j)-flx(i,j))+ &
(fly(i,j+1)-fly(i,j)) )*dt2*scali(i,j)
q=fld(i,j)*(fco(i,j)+onemu)-flxdiv(i,j)
!max,min should only be active for very thin layers
fldlo(i,j)=max( fmn(i,j), min( fmx(i,j), &
q/(fcn(i,j)+onemu) ))
fmxlo(i,j) = max(fld(i,j),fldc(i,j),fldlo(i,j))
fmnlo(i,j) = min(fld(i,j),fldc(i,j),fldlo(i,j))
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(fldlo, ip,'ad:610:fldlo')
call pipe_compare_sym1(flxdiv, ip,'ad:610:flxdv')
endif
!
if (ldebug_advem .and. itests.gt.0 .and. jtests.gt.0) then
i=itests
j=jtests
write (lp,'(a,2i5,3f10.5)') &
'advem: fldlo,rng ',i+i0,j+j0, &
fldlo(i,j),fmnlo(i,j),fmxlo(i,j)
endif
!
!.....Leapfrog step using high order scheme
!
! --- rhs: u, v, fld+, flx, fly
! --- lhs: fax, fay
!
margin = mbdy_a - 2
!
!$OMP PARALLEL DO PRIVATE(j,i,q,jb,ja,ib,ia,fhx,fhy) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_U) then
fhx=u(i,j)*0.5*(fldc(i,j)+fldc(i-1,j)) ! 2nd order in space
fax(i,j)= fhx-flx(i,j) ! anti-diffusion x-flux
endif !iu
if (SEA_V) then
fhy=v(i,j)*0.5*(fldc(i,j)+fldc(i,j-1)) ! 2nd order in space
fay(i,j)= fhy-fly(i,j) ! anti-diffusion y-flux
endif !iv
enddo !i
enddo !j
!$OMP END PARALLEL DO
do j=1-margin,jj+margin
do l=1,isp(j) !ok
if (ifp(j,l).ge. 1-margin) then
fax(ifp(j,l) ,j)=0.0
endif
if (ilp(j,l).lt.ii+margin) then
fax(ilp(j,l)+1,j)=0.0
endif
enddo !l
enddo !j
!
do i=1-margin,ii+margin
do l=1,jsp(i) !ok
if (jfp(i,l).ge. 1-margin) then
fay(i,jfp(i,l) )=0.0
endif
if (jlp(i,l).lt.jj+margin) then
fay(i,jlp(i,l)+1)=0.0
endif
enddo !l
enddo !i
!========================================================
!
! --- finish computation of antidiffusive fluxes
!
! --- rhs: fmnlo+,fmxlo+,fax+,fay+,fldlo,fcn,scal
! --- lhs: rp, rm
!
margin = mbdy_a - 3
!
qdt2 = 1.0/dt2
!$OMP PARALLEL DO PRIVATE(j,i,ia,ib,ja,jb, &
!$OMP fqmax,fqmin,famax,famin,qp,qm) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
ia=ipim1(i,j) !i-1 if sea and i if land
ib=ipip1(i,j) !i+1 if sea and i if land
ja=ipjm1(i,j) !j-1 if sea and j if land
jb=ipjp1(i,j) !j+1 if sea and j if land
fqmax = max(fmxlo(i,j),fmxlo(ia,j),fmxlo(ib,j), &
fmxlo(i,ja),fmxlo(i,jb))
fqmin = min(fmnlo(i,j),fmnlo(ia,j),fmnlo(ib,j), &
fmnlo(i,ja),fmnlo(i,jb))
famax = max(0.0,fax(i, j) ) - min(0.0,fax(ib,j) ) + &
max(0.0,fay(i, j) ) - min(0.0,fay(i, jb))
famin = max(0.0,fax(ib,j) ) - min(0.0,fax(i, j) ) + &
max(0.0,fay(i, jb)) - min(0.0,fay(i, j) )
if (famax > 0.0) then
qp = (fqmax-fldlo(i,j)) *fcn(i,j)*scal(i,j)*qdt2
rp(i,j) = min(1.0, qp/famax)
else
rp(i,j) = 0.0
endif
if (famin > 0.0) then
qm = (fldlo(i,j)-fqmin) *fcn(i,j)*scal(i,j)*qdt2
rm(i,j) = min(1.0, qm/famin)
else
rm(i,j) = 0.0
endif
fmx(i,j) = fqmax !less restrictive maximum
fmn(i,j) = fqmin !less restrictive minimum
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
!
if (ldebug_advem .and. itests.gt.0 .and. jtests.gt.0) then
i=itests
j=jtests
write (lp,'(a,2i5,3f10.5)') &
'advem: fldc,rngfq',i+i0,j+j0, &
fldc(i,j),fmn(i,j),fmx(i,j)
endif
!
! --- rhs: rp+, rm+
! --- lhs: fax, fay
!
margin = mbdy_a - 4
!
!$OMP PARALLEL DO PRIVATE(j,i,fact) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_U) then
if (fax(i,j) < 0.0) then
fact = min(rp(i-1,j),rm(i,j))
else
fact = min(rp(i,j),rm(i-1,j))
endif
fax(i,j) = fact*fax(i,j)
endif !iu
if (SEA_V) then
if (fay(i,j) < 0.0) then
fact = min(rp(i,j-1),rm(i,j))
else
fact = min(rp(i,j),rm(i,j-1))
endif
fay(i,j) = fact*fay(i,j)
endif !iv
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym2(flx, iu,'ad:18:flx ', &
fly, iv,'ad:18:fly ')
endif
!
!diag i=itests
!diag j=jtests
!diag write (lp,'(''advem (2)'',2i5,f22.3/1pe39.2/0pf21.3,1pe9.2,0pf9.3, &
!diag 1pe9.2,0pf9.3/1pe39.2/0pf39.3)') i,j,fldlo(i-1,j),u(i,j),fldlo(i,j-1), &
!diag v(i,j),fldlo(i,j),v(i,j+1),fldlo(i,j+1),u(i+1,j),fldlo(i+1,j)
!
! --- rhs: fax+, fay+, fld, fcn, fmx, fmn
! --- lhs: fld
!
margin = mbdy_a - 5
!
!$OMP PARALLEL DO PRIVATE(j,i) &
!$OMP SCHEDULE(STATIC,jblk)
do j=1-margin,jj+margin
do i=1-margin,ii+margin
if (SEA_P) then
fldao(i,j) = fld(i,j)*fco(i,j)*scal(i,j)
!
!...........apply antidiffusive flux correction
flxdiv(i,j)=((fax(i+1,j)-fax(i,j))+ &
(fay(i,j+1)-fay(i,j)) )*dt2*scali(i,j)
!max,min should only be active for very thin layers
fld(i,j)=max( fmn(i,j), min( fmx(i,j), &
fldlo(i,j)-flxdiv(i,j)/(fcn(i,j)+onemu) ))
!
fldan(i,j) = fld(i,j)*fcn(i,j)*scal(i,j)
endif !ip
enddo !i
enddo !j
!$OMP END PARALLEL DO
if (lpipe .and. lpipe_advem) then
! --- compare two model runs.
call pipe_compare_sym1(flxdiv, ip,'ad:620:flxdv')
call pipe_compare_sym1(fld, ip,'ad:1620:fld ')
endif
!
if (ldebug_advem .and. itests.gt.0 .and. jtests.gt.0) then
i=itests
j=jtests
write (lp,'(a,2i5,f10.5)') &
'advem: fld ',i+i0,j+j0, &
fld(i,j)
endif
return
end subroutine advem_fct2
subroutine advem_fct2c(fld,fldc,u,v,fco,fcn, scal,scali,dt2)
implicit none
!
real, intent(in) :: dt2
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(inout) :: fld
real, dimension (1-nbdy:idm+nbdy,1-nbdy:jdm+nbdy), &
intent(in) :: fldc,u,v,scal,scali,fco,fcn
!
! Leapfrog 2nd order FCT