build.gradle.kts

import org.jetbrains.dokka.DokkaConfiguration
import org.jetbrains.dokka.gradle.DokkaTask

plugins {
    id("com.android.library") version "8.2"
    kotlin("multiplatform") version "1.9.10"
    kotlin("plugin.serialization") version "1.9.10"
    id("com.goncalossilva.resources") version "0.3.2"
    id("org.jlleitschuh.gradle.ktlint") version "11.5.0"
    id("org.jetbrains.dokka") version "1.8.20"
    id("convention.publication")
}

group = "io.polywrap"
version = "0.10.4"

repositories {
    google()
    mavenCentral()
    maven { url = uri("https://s01.oss.sonatype.org/content/repositories/snapshots/") }
}

kotlin {
    jvm {
        jvmToolchain(17)
        testRuns["test"].executionTask.configure {
            useJUnitPlatform()
        }
    }
    androidTarget {
        publishLibraryVariants("release")
    }

    sourceSets {
        val commonMain by getting {
            dependencies {
                api("io.polywrap:polywrap-native:0.10.6")
                api("com.ensarsarajcic.kotlinx:serialization-msgpack:0.5.5")
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-core:1.5.1")
                implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.7.3")
            }
        }
        val commonTest by getting {
            kotlin.srcDirs("$projectDir/examples")
            dependencies {
                implementation(kotlin("test"))
                implementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.7.3")
                implementation("com.goncalossilva:resources:0.3.2") // access resources in tests
                // client test
                implementation("com.ionspin.kotlin:bignum:0.3.8")
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.5.1")
            }
        }
    }
}

android {
    namespace = "io.polywrap.polywrapClient"
    compileSdk = 32
    defaultConfig.minSdk = 24
    compileOptions {
        targetCompatibility = JavaVersion.VERSION_17
    }
    testOptions {
        unitTests.all {
            it.enabled = false
        }
    }
}

// javadoc generation for Maven repository publication
tasks.register<Jar>("dokkaJavadocJar") {
    dependsOn(tasks.dokkaJavadoc)
    from(tasks.dokkaJavadoc.flatMap { it.outputDirectory })
    archiveClassifier.set("javadoc")
}

// generate dokka html site and copy it to docs folder
tasks.register<Copy>("copyDokkaHtml") {
    dependsOn(tasks.dokkaHtml)
    val docsDir = "$projectDir/docs"
    doFirst { delete(docsDir) }
    from("${layout.buildDirectory.get()}/dokka/html")
    into(docsDir)
}
// automatically generate docs site when publishing
if (!version.toString().endsWith("-SNAPSHOT")) {
    tasks.getByName("publish").dependsOn("copyDokkaHtml")
}

// print stdout during tests
tasks.withType<Test> {
    this.testLogging {
        this.showStandardStreams = true
    }
}

// lint configuration
configure<org.jlleitschuh.gradle.ktlint.KtlintExtension> {
    disabledRules.set(setOf("no-wildcard-imports"))
    filter {
        exclude("**/build/**")
        exclude("**/generated/**")
        exclude("**/resources/**")
        exclude("**/test/**")
        exclude("**/wrap/**")
    }
}
// ktlint has a bug where 'exclude' does not work, so this is a workaround
tasks {
    listOf(
        runKtlintCheckOverCommonMainSourceSet,
        runKtlintCheckOverCommonTestSourceSet,
        runKtlintCheckOverKotlinScripts
    ).forEach {
        it {
            setSource(
                project.sourceSets.map { sourceSet ->
                    sourceSet.allSource.filter { file ->
                        !file.path.contains("/generated/") &&
                            !file.path.contains("build.gradle.kts")
                    }
                }
            )
        }
    }
}

// dokka configuration
tasks.withType<DokkaTask>().configureEach {
    dokkaSourceSets {
        configureEach {
            documentedVisibilities.set(
                setOf(
                    DokkaConfiguration.Visibility.PUBLIC,
                    DokkaConfiguration.Visibility.PROTECTED
                )
            )
        }
    }
}