build.gradle

plugins {
	id 'java-library'
	id 'scala'
	id 'maven-publish'
	id 'signing'
	id 'idea'
}

// version = '1.1.1'  // Last released version
version '1.1.2-SNAPSHOT'

group 'com.xebialabs.restito'

defaultTasks 'build'



sourceCompatibility = '11'
targetCompatibility = '11'

repositories {
	mavenCentral()
	mavenLocal()
}

dependencies {
	testCompileOnly 'org.scala-lang:scala-library:2.12.16'

	testImplementation 'org.slf4j:slf4j-simple:1.7.21'
	
	testImplementation 'org.mockito:mockito-core:4.8.0'
	testImplementation 'org.hamcrest:hamcrest:2.2'
	testImplementation 'io.rest-assured:rest-assured:5.2.0'

	testImplementation"com.typesafe.akka:akka-actor_2.12:2.5.17"
	testImplementation"com.typesafe.akka:akka-stream_2.12:2.5.17"
	testImplementation"com.typesafe.akka:akka-http_2.12:10.1.5"
	testImplementation"org.scalatest:scalatest_2.12:3.0.5"

	api 'org.glassfish.grizzly:grizzly-http-server:2.3.25'
	implementation 'junit:junit:4.13.2'
	implementation 'org.slf4j:slf4j-api:1.7.21'
	implementation 'com.jayway.jsonpath:json-path:2.7.0'
	implementation 'org.apache.mina:mina-core:2.1.6'
}

java {
	withSourcesJar()
	withJavadocJar()
}

test {
	testLogging {
		events "PASSED", "SKIPPED", "FAILED"
		exceptionFormat 'full'
	}
}

tasks.withType(JavaCompile) { compile ->
	compile.options.compilerArgs << '-Xlint:deprecation'
	compile.options.compilerArgs << '-Xlint:unchecked'
}

artifacts {
	archives sourcesJar
	archives javadocJar
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifactId = 'restito'
			from components.java

			pom {
				name = 'Restito'
				description = 'Restito - testing framework for rest clients'
				packaging = 'jar'
				url = 'http://mkotsur.github.com/restito'

				licenses {
					license {
						name = 'MIT'
						url = 'https://raw.github.com/mkotsur/restito/master/LICENSE'
					}
				}

				developers {
					developer {
						id = 'mkotsur'
						name = 'Mike Kotsur'
						email = 'miccots@gmail.com'
					}
				}
				scm {
					url = 'scm:git@github.com:mkotsur/restito.git'
					connection = 'scm:git@github.com:mkotsur/restito.git'
					developerConnection = 'scm:git@github.com:mkotsur/restito.git'
				}
			}
		}
	}

	repositories {
		if (project.hasProperty("sonatypeUsername")) {
			maven {
				url = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
				credentials {
					username = sonatypeUsername
					password = sonatypePassword
				}
				mavenContent {
					releasesOnly()
				}
			}
		}

		mavenLocal {
			mavenContent {
				snapshotsOnly()
			}
		}
	}

}

signing {
	sign publishing.publications.mavenJava
}