build.gradle

plugins {
    id 'java'
    id 'signing'
    id 'maven-publish'
    id "com.diffplug.spotless" version "6.25.0"
    id "com.github.spotbugs" version "6.0.26"
}

var javaToolchain = System.getenv('JAVA_TOOLCHAIN')

java {
    // If running from CI, the tool chain will be present
    if (javaToolchain != null) {
        toolchain {
            languageVersion = JavaLanguageVersion.of(javaToolchain)
        }
    }
}

compileJava {
    if (javaToolchain != "8") {
        options.release = 8
    }
    options.compilerArgs.add('-Xlint')
}

compileTestJava {
    if (javaToolchain != "8") {
        options.release = 8
    }
    options.compilerArgs.add('-Xlint')
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    // log
    testImplementation 'org.slf4j:jul-to-slf4j:2.0.16'
    testRuntimeOnly 'ch.qos.logback:logback-classic:1.3.14'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.11.3'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.11.3'

}

spotless {
    java {
         // remove when spotless moved to this Palantir version
         palantirJavaFormat("2.38.0")
    }
}

spotbugs {
    ignoreFailures = false
    showProgress = true
    reportsDir = file("$buildDir/spotbugs")
}

spotbugsMain {
    excludeFilter = file('spotbugs-exclude.xml')
    reports {
        html {
            required = true
            outputLocation = file("$buildDir/reports/spotbugs/spotbugs.html")
        }
    }
}

spotbugsTest {
    excludeFilter = file('spotbugs-exclude-tests.xml')
    reports {
        html {
            required = true
            outputLocation = file("$buildDir/reports/spotbugs/spotbugsTest.html")
        }
    }
}

test {
    useJUnitPlatform()

    // override security properties enabling all options
    systemProperty "java.security.properties", "java.security.override"
    systemProperty "junit.jupiter.extensions.autodetection.enabled", "true"
}

javadoc {
    exclude "tlschannel/impl"
    exclude "tlschannel/util"
}

java {
    withSourcesJar()
    withJavadocJar()
}

// see tlschannel.AllocationTest for comment about this
task allocationTest(type: JavaExec) {
    classpath = sourceSets.test.runtimeClasspath
    mainClass = 'tlschannel.AllocationTest'
    jvmArgs = ['-XX:+UnlockExperimentalVMOptions', '-XX:+UseEpsilonGC']
}

check.dependsOn allocationTest

publishing {
    publications {
        tlschannel(MavenPublication) {
            groupId = 'com.github.marianobarrios'
            artifactId = 'tls-channel'
            version = '0.10.0-SNAPSHOT'
            from components.java
            pom {
                name = 'TLS Channel'
                description = 'A Java library that implements a ByteChannel interface over SSLEngine, ' +
                        'enabling easy-to-use (socket-like) TLS for Java applications. '
                url = 'https://github.com/marianobarrios/tls-channel'
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }
                developers {
                    developer {
                        name = 'Mariano Barrios'
                        email = 'marbar@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git@github.com:marianobarrios/tlschannel.git'
                    developerConnection = 'scm:git:ssh://example.com/my-library.git'
                    url = 'scm:git@github.com:marianobarrios/tlschannel.git'
                }
            }
        }
    }
    repositories {
        maven {
            url = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
            credentials {
                username = project.findProperty('sonatypeUsername')
                password = project.findProperty('sonatypePassword')
            }
        }
    }
}

signing {
    sign publishing.publications.tlschannel
}