forked from ben-manes/caffeine
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
160 lines (131 loc) · 4.51 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
import net.ltgt.gradle.errorprone.CheckSeverity
apply plugin: 'io.github.gradle-nexus.publish-plugin'
apply plugin: 'org.kordamp.gradle.source-stats'
apply plugin: 'com.github.ben-manes.versions'
apply plugin: 'com.github.kt3k.coveralls'
apply plugin: 'jacoco'
buildscript {
apply from: "${rootDir}/gradle/dependencies.gradle"
repositories {
gradlePluginPortal()
mavenCentral()
}
dependencies {
classpath gradlePlugins.values()
}
}
buildScan {
termsOfServiceAgree = 'yes'
termsOfServiceUrl = 'https://gradle.com/terms-of-service'
}
tasks.register('testReport', TestReport) {
group = 'Build'
description = 'Generates an aggregate test report'
destinationDir = file("${buildDir}/reports/allTests")
}
allprojects {
apply plugin: 'com.github.ethankhall.semantic-versioning'
apply from: "${rootDir}/gradle/eclipse.gradle"
repositories {
mavenCentral()
}
group = 'com.github.ben-manes.caffeine'
version.with {
major = 3 // incompatible API changes
minor = 0 // backwards-compatible additions
patch = 5 // backwards-compatible bug fixes
releaseBuild = rootProject.hasProperty('release')
}
}
subprojects {
apply plugin: 'biz.aQute.bnd.builder'
apply plugin: 'java-library'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply from: "${rootDir}/gradle/publish.gradle"
apply from: "${rootDir}/gradle/codeQuality.gradle"
apply from: "${rootDir}/gradle/dependencies.gradle"
apply from: "${rootDir}/gradle/objectLayout.gradle"
java.toolchain.languageVersion = JavaLanguageVersion.of(System.env.'JAVA_VERSION' ?: 11)
configurations {
all {
exclude group: 'org.hamcrest', module: 'hamcrest-core'
}
}
dependencies {
testImplementation libraries.guava
testImplementation testLibraries.truth
testImplementation testLibraries.mockito
testImplementation testLibraries.hamcrest
testImplementation testLibraries.awaitility
testImplementation testLibraries.osgiCompile
testRuntimeOnly testLibraries.osgiRuntime
}
tasks.register('bundle', aQute.bnd.gradle.Bundle) {
from sourceSets.main.output
sourceSet = sourceSets.main
}
tasks.withType(JavaCompile).configureEach {
if (name.contains('Test') || name.contains('Jmh')) {
options.errorprone.nullaway {
severity = CheckSeverity.OFF
}
}
}
tasks.withType(Test).configureEach {
rootProject.testReport.reportOn it
it.dependsOn(jar)
// ensure tasks don't overwrite the default report directories used by the 'test' task
reports.html.destination = file("${buildDir}/reports/${name}")
reports.junitXml.destination = file("${buildDir}/reports/${name}/results")
binaryResultsDirectory = file("${buildDir}/reports/${name}/results/binary/${name}")
}
if (project != project(':caffeine')) {
javadoc.options.linksOffline(
"https://static.javadoc.io/${group}/caffeine/${version}/",
"${project(':caffeine').buildDir}/docs/javadoc/",
)
javadoc.dependsOn(project(':caffeine').javadoc)
}
}
nexusPublishing {
repositories {
sonatype {
username = project.properties['nexusUsername'] ?: System.env.'NEXUS_USERNAME'
password = project.properties['nexusPassword'] ?: System.env.'NEXUS_PASSWORD'
}
}
}
// Only report code coverage for projects that are distributed
def publishedProjects = subprojects.findAll { it.path != ':simulator' }
tasks.register('jacocoMerge', JacocoMerge) {
publishedProjects.each { subproject ->
executionData subproject.tasks.withType(Test)
}
doFirst {
executionData = files(executionData.findAll { it.exists() })
}
}
tasks.register('jacocoRootReport', JacocoReport) {
group = 'Coverage reports'
description = 'Generates an aggregate report from all subprojects'
dependsOn publishedProjects.test, jacocoMerge
additionalSourceDirs.from = files(publishedProjects.sourceSets.main.allSource.srcDirs)
sourceDirectories.from = files(publishedProjects.sourceSets.main.allSource.srcDirs)
classDirectories.from = files(publishedProjects.sourceSets.main.output)
executionData jacocoMerge.destinationFile
reports {
html.required = true // human readable
xml.required = true // required by coveralls
}
}
coveralls {
sourceDirs = publishedProjects.sourceSets.main.allSource.srcDirs.flatten()
jacocoReportPath = "${buildDir}/reports/jacoco/jacocoRootReport/jacocoRootReport.xml"
}
tasks.named('coveralls').configure {
group = 'Coverage reports'
description = 'Uploads the aggregated coverage report to Coveralls'
dependsOn jacocoRootReport
onlyIf { System.env.'CI' }
}