build.gradle

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'

group = 'be.jlr-home.gradle'
version = '0.1.1'

repositories {
    mavenCentral()
}

dependencies {
    compile gradleApi()
    compile localGroovy()

    compile 'net.sourceforge.plantuml:plantuml:8001'
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name 'Gradle PlantUML Plugin'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'A wrapper around PlantUML so it can be easily used in gradle to create diagrams defined in your java source.'
                url 'https://github.com/janvolck/gradle-plantuml-plugin'

                scm {
                    connection 'scm:git:git@github.com:janvolck/gradle-plantuml-plugin.git'
                    developerConnection 'scm:git:git@github.com:janvolck/gradle-plantuml-plugin.git'
                    url 'git@github.com:janvolck/gradle-plantuml-plugin.git'
                }

                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id 'janvolck'
                        name 'Jan Volckaert'
                        email 'janvolck@jlr-home.be'
                    }
                }
            }
        }
    }
}