build.gradle

plugins {
    id 'java'
    id 'java-library'
    id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11

allprojects {
	group 'illogicworks'
	version '0.2'

	repositories {
    	maven {
        	url "https://maven.fabricmc.net/"
    	}
    	mavenCentral()
	}
	
	tasks.withType(JavaCompile).configureEach {
		// We want Deimos to enforce at least Java 11.
		// Only limited to 11 given the computers at university don't have newer versions
		it.options.release = 11
	}
}

dependencies {
    api 'net.fabricmc:fabric-loader:0.14.17'

    // fabric-loader dependencies, for some reason they're not in its pom

    // https://mvnrepository.com/artifact/org.ow2.asm/asm
    
    implementation "org.ow2.asm:asm:${project.asm_version}"
    implementation "org.ow2.asm:asm-analysis:${project.asm_version}"
    implementation "org.ow2.asm:asm-commons:${project.asm_version}"
    implementation "org.ow2.asm:asm-tree:${project.asm_version}"
    implementation "org.ow2.asm:asm-util:${project.asm_version}"

    api("net.fabricmc:sponge-mixin:${project.mixin_version}") {
        exclude module: 'launchwrapper'
        exclude module: 'guava'
    }
    implementation 'net.fabricmc:access-widener:2.1.0'

    // needed by fabric loader, although we don't need remapping
    implementation 'net.fabricmc:tiny-mappings-parser:0.3.0+build.17'
    implementation 'net.fabricmc:tiny-remapper:0.8.2'
}

task Run(type: JavaExec) {
    classpath sourceSets.main.runtimeClasspath
    mainClass = "net.fabricmc.loader.impl.launch.knot.KnotClient"
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
			artifactId = 'deimos'
		}
	}
}