-
Notifications
You must be signed in to change notification settings - Fork 20
/
MSABasic.sol
272 lines (252 loc) · 9.05 KB
/
MSABasic.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;
import "./lib/ModeLib.sol";
import { ExecutionLib } from "./lib/ExecutionLib.sol";
import { ExecutionHelper } from "./core/ExecutionHelper.sol";
import { PackedUserOperation } from "account-abstraction/interfaces/PackedUserOperation.sol";
import { IERC7579Account } from "./interfaces/IERC7579Account.sol";
import { IMSA } from "./interfaces/IMSA.sol";
import "./interfaces/IERC7579Module.sol";
import { ModuleManager } from "./core/ModuleManager.sol";
/**
* @author zeroknots.eth | rhinestone.wtf
* Reference implementation of a very simple ERC7579 Account.
* This account only implements CallType: SINGLE and BATCH.
* only the default ExecType is implemented.
* Hook support is not implemented
*/
contract MSABasic is IMSA, ExecutionHelper, ModuleManager {
using ExecutionLib for bytes;
using ModeLib for ModeCode;
/**
* @inheritdoc IERC7579Account
*/
function execute(
ModeCode mode,
bytes calldata executionCalldata
)
external
payable
onlyEntryPointOrSelf
{
CallType callType = mode.getCallType();
if (callType == CALLTYPE_BATCH) {
Execution[] calldata executions = executionCalldata.decodeBatch();
_execute(executions);
} else if (callType == CALLTYPE_SINGLE) {
(address target, uint256 value, bytes calldata callData) =
executionCalldata.decodeSingle();
_execute(target, value, callData);
} else {
revert UnsupportedCallType(callType);
}
}
/**
* @inheritdoc IERC7579Account
*/
function executeFromExecutor(
ModeCode mode,
bytes calldata executionCalldata
)
external
payable
onlyExecutorModule
returns (
bytes[] memory returnData // TODO returnData is not used
)
{
CallType callType = mode.getCallType();
if (callType == CALLTYPE_BATCH) {
Execution[] calldata executions = executionCalldata.decodeBatch();
returnData = _execute(executions);
} else if (callType == CALLTYPE_SINGLE) {
(address target, uint256 value, bytes calldata callData) =
executionCalldata.decodeSingle();
returnData = new bytes[](1);
returnData[0] = _execute(target, value, callData);
} else {
revert UnsupportedCallType(callType);
}
}
/**
* @dev ERC-4337 executeUserOp according to ERC-4337 v0.7
* This function is intended to be called by ERC-4337 EntryPoint.sol
* @dev Ensure adequate authorization control: i.e. onlyEntryPointOrSelf
* The implementation of the function is OPTIONAL
*
* @param userOp PackedUserOperation struct (see ERC-4337 v0.7+)
*/
function executeUserOp(
PackedUserOperation calldata userOp,
bytes32 userOpHash
)
external
payable
onlyEntryPoint
{
bytes calldata callData = userOp.callData[4:];
(bool success,) = address(this).delegatecall(callData);
if (!success) revert ExecutionFailed();
}
/**
* @inheritdoc IERC7579Account
*/
function installModule(
uint256 moduleTypeId,
address module,
bytes calldata initData
)
external
payable
onlyEntryPointOrSelf
{
if (!IModule(module).isModuleType(moduleTypeId)) revert MismatchModuleTypeId(moduleTypeId);
if (moduleTypeId == MODULE_TYPE_VALIDATOR) _installValidator(module, initData);
else if (moduleTypeId == MODULE_TYPE_EXECUTOR) _installExecutor(module, initData);
else if (moduleTypeId == MODULE_TYPE_FALLBACK) _installFallbackHandler(module, initData);
else revert UnsupportedModuleType(moduleTypeId);
emit ModuleInstalled(moduleTypeId, module);
}
/**
* @inheritdoc IERC7579Account
*/
function uninstallModule(
uint256 moduleTypeId,
address module,
bytes calldata deInitData
)
external
payable
onlyEntryPointOrSelf
{
if (moduleTypeId == MODULE_TYPE_VALIDATOR) {
_uninstallValidator(module, deInitData);
} else if (moduleTypeId == MODULE_TYPE_EXECUTOR) {
_uninstallExecutor(module, deInitData);
} else if (moduleTypeId == MODULE_TYPE_FALLBACK) {
_uninstallFallbackHandler(module, deInitData);
} else {
revert UnsupportedModuleType(moduleTypeId);
}
emit ModuleUninstalled(moduleTypeId, module);
}
/**
* @dev ERC-4337 validateUserOp according to ERC-4337 v0.7
* This function is intended to be called by ERC-4337 EntryPoint.sol
* this validation function should decode / sload the validator module to validate the userOp
* and call it.
*
* @dev MSA MUST implement this function signature.
* @param userOp PackedUserOperation struct (see ERC-4337 v0.7+)
*/
function validateUserOp(
PackedUserOperation calldata userOp,
bytes32 userOpHash,
uint256 missingAccountFunds
)
external
payable
virtual
onlyEntryPoint
payPrefund(missingAccountFunds)
returns (uint256 validSignature)
{
address validator;
// @notice validator encoding in nonce is just an example!
// @notice this is not part of the standard!
// Account Vendors may choose any other way to implement validator selection
uint256 nonce = userOp.nonce;
assembly {
validator := shr(96, nonce)
}
// check if validator is enabled. If not terminate the validation phase.
if (!_isValidatorInstalled(validator)) return VALIDATION_FAILED;
// bubble up the return value of the validator module
validSignature = IValidator(validator).validateUserOp(userOp, userOpHash);
}
/**
* @dev ERC-1271 isValidSignature
* This function is intended to be used to validate a smart account signature
* and may forward the call to a validator module
*
* @param hash The hash of the data that is signed
* @param data The data that is signed
*/
function isValidSignature(
bytes32 hash,
bytes calldata data
)
external
view
virtual
override
returns (bytes4)
{
address validator = address(bytes20(data[0:20]));
if (!_isValidatorInstalled(validator)) revert InvalidModule(validator);
return IValidator(validator).isValidSignatureWithSender(msg.sender, hash, data[20:]);
}
/**
* @dev Initializes the account. Function might be called directly, or by a Factory
* @param data. encoded data that can be used during the initialization phase
*/
function initializeAccount(bytes calldata data) public payable virtual {
// checks if already initialized and reverts before setting the state to initialized
_initModuleManager();
// this is just implemented for demonstration purposes. You can use any other initialization
// logic here.
(address bootstrap, bytes memory bootstrapCall) = abi.decode(data, (address, bytes));
(bool success,) = bootstrap.delegatecall(bootstrapCall);
if (!success) revert AccountInitializationFailed();
}
/**
* @inheritdoc IERC7579Account
* @param additionalContext is not needed here. It is only used in cases where the modules are
* stored in more complex mappings
*/
function isModuleInstalled(
uint256 moduleTypeId,
address module,
bytes calldata additionalContext
)
external
view
override
returns (bool isInstalled)
{
if (moduleTypeId == MODULE_TYPE_VALIDATOR) {
return _isValidatorInstalled(module);
} else if (moduleTypeId == MODULE_TYPE_EXECUTOR) {
return _isExecutorInstalled(module);
} else if (moduleTypeId == MODULE_TYPE_FALLBACK) {
return _isFallbackHandlerInstalled(abi.decode(additionalContext, (bytes4)), module);
} else {
return false;
}
}
/**
* @inheritdoc IERC7579Account
*/
function accountId() external view virtual override returns (string memory) {
// vendor.flavour.semver
return "uMSA.simple/noHook.v0.1";
}
/**
* @inheritdoc IERC7579Account
*/
function supportsExecutionMode(ModeCode mode) external view virtual override returns (bool) {
CallType callType = mode.getCallType();
if (callType == CALLTYPE_BATCH) return true;
else if (callType == CALLTYPE_SINGLE) return true;
else return false;
}
/**
* @inheritdoc IERC7579Account
*/
function supportsModule(uint256 modulTypeId) external view virtual override returns (bool) {
if (modulTypeId == MODULE_TYPE_VALIDATOR) return true;
else if (modulTypeId == MODULE_TYPE_EXECUTOR) return true;
else if (modulTypeId == MODULE_TYPE_FALLBACK) return true;
else return false;
}
}