build.gradle

buildscript {
	repositories {
		maven {
			url("https://plugins.gradle.org/m2/")
		}
	}
	dependencies {
		classpath("com.diffplug.spotless:spotless-plugin-gradle:3.4.0")
		classpath("org.springframework.boot:spring-boot-gradle-plugin:1.5.6.RELEASE")
	}
}

apply plugin: 'org.springframework.boot'

dependencies {
	compile(project(':rest'))
	compile('org.springframework.boot:spring-boot-starter-web:1.5.6.RELEASE')
	testCompile('org.springframework.boot:spring-boot-starter-test:1.5.6.RELEASE')
}

allprojects{

	buildscript {
		repositories {
			maven {
				url("https://plugins.gradle.org/m2/")
			}
		}
	}

	apply plugin: 'java'
	apply plugin: 'idea'
	apply plugin: 'com.diffplug.gradle.spotless'

	version = '0.0.1-SNAPSHOT'
	sourceCompatibility = 1.8

	repositories {
		jcenter()
	}

	dependencies{
		compile('org.apache.commons:commons-lang3:3.6')
		testCompile('org.mockito:mockito-core:2.8.47')
		testCompile('org.assertj:assertj-core:3.8.0')
		testCompile('junit:junit:4.12')
	}

	idea {
		module {
			inheritOutputDirs = true
			downloadJavadoc = true
			downloadSources = true
			outputDir = file('build/classes/main')
			testOutputDir = file('build/classes/test')
		}
	}

	spotless {
		format 'misc', {
			target '**/*.gradle', '**/*.md', '**/.gitignore'

			trimTrailingWhitespace()
			indentWithTabs() // or spaces. Takes an integer argument if you don't like 4
			endWithNewline()
		}
	}
}

idea {
	project {
		jdkName = '1.8'
		languageLevel = '8'
		vcs = 'Git'
	}
}

spotless {
	java {
		removeUnusedImports()
		importOrderFile 'src/main/resources/formatter/spotless.importorder'
		eclipse().configFile 'src/main/resources/formatter/spotless.eclipse-format.xml'
	}
}

bootRepackage {
	mainClass = 'io.reflectoring.raito4rpi.Raito4RPiApplication'
}