How do I navigate from find_timing_paths to the ODB objects?

[oharboe]

I would like to create a 3d graph in python for megaboom to see the skew as a function of x and y on the design as I was inspired by slide 20 in https://www.eng.biu.ac.il/temanad/files/2017/02/Lecture-8-CTS.pdf

(Of course this is just a heatmap, the 3d bit is just bling, but helps create a sense of what is going on)

Here is a first attempt, using slack instead of skew, I don't know how to get from a timing path to skew, although the OpenROAD GUI shows skew per path. Though from the slack and x,y I do get a sense of what is going on.

However, I haven't found a reasonable way to map a skew to an x,y location. The transition from find_timing_paths to the ODB objects is particularly awkward/hacky below...

Any pointers on how to perfom going from find_timing_slack to skew & x,y position in tcl?

source $::env(SCRIPTS_DIR)/load.tcl
load_design 4_cts.odb 4_cts.sdc

set paths [find_timing_paths -path_group reg2reg -sort_by_slack -group_count 1000]

set db [::ord::get_db]
set block [[$db getChip] getBlock]

# open file
set fp [open $::env(OUTPUT) w]
foreach path $paths {
  set endpoint [get_property $path endpoint]
  set instance [$endpoint instance]
  set name [get_property $endpoint full_name]
  set slack [get_property $path slack]

  # If DFF is in the $name and it ends with /D
  if {[regexp {DFF} $name] && [regexp {/D$} $name]} {
    # remove the /D suffix
    set name [string range $name 0 end-2]
    # replace [ and ] with \[ and \]
    set name [string map { {[} {\[} {]} {\]} } $name]
    set b [$block findInst $name]
    set bbox [$b getBBox]
    puts $fp "$name $slack [$bbox xMin] [$bbox yMin]"
  }
}
close $fp

[oharboe]

Seen from this angle, it is effectively a heatmap. This is with 10000 WNS paths. This is corroborating that global placement merits further study.

Tinkering a bit more and checking that I'm getting roughly the right coordinate, I can see that the WNS is in the same location in the plot and in OpenROAD GUI

Bumped to 1000000 paths:

[maliberty]

I think you want the sta_to_db_* functions from dbSta.i

[oharboe]

Will try, thanks!

Is there a way to get the skew from a path in tcl, same as the GUI?

[maliberty]

I don't know of one but you could ask in the sta repo

[oharboe]

I think you want the sta_to_db_* functions from dbSta.i

$ make RUN_SCRIPT=slack-positions.tcl run
[deleted]
Expected instance NULL
make: *** [Makefile:1076: run] Error 1

source $::env(SCRIPTS_DIR)/load.tcl
load_design 4_cts.odb 4_cts.sdc

set paths [find_timing_paths -path_group reg2reg -sort_by_slack -group_count 1000000]

set db [::ord::get_db]
set block [[$db getChip] getBlock]

set path [lindex $paths 0]
set endpoint [get_property $path endpoint]
set instance [sta::sta_to_db_inst [$endpoint instance]]
puts "Expected instance $instance"
set name [get_property $endpoint full_name]
set slack [get_property $path slack]
set bbox [$instance getBBox]
puts "$name $slack [$bbox xMin] [$bbox yMin]"

[maliberty]

Those plots are labeled DELAY and Skew which shows some inconsistency. I think they are measuring delay from the driver to a sequential not really a skew (I am guessing). If you see two points at different heights there is no way to know whether a path exists.

[oharboe]

I meant in the Timing Report:

[oharboe]

Seems to work now, less slack:

source $::env(SCRIPTS_DIR)/load.tcl
load_design 4_cts.odb 4_cts.sdc

set paths [find_timing_paths -path_group reg2reg -sort_by_slack -group_count 1000000]

set db [::ord::get_db]
set block [[$db getChip] getBlock]

foreach path $paths {
  set endpoint [get_property $path endpoint]
  set instance [sta::sta_to_db_inst [$endpoint instance]]
  set port [sta::sta_to_db_port [$endpoint port]]
  set name [get_property $endpoint full_name]
  set obj {NULL}
  if {$port!={NULL}} {
    set obj $port
  } elseif {$instance!={NULL}} {
    set obj $instance
  } else {
    puts "Nothing found for $name"
    continue
  }
  set slack [get_property $path slack]
  set bbox [$obj getBBox]
  puts "$name $slack [ord::dbu_to_microns [$bbox xMin]] [ord::dbu_to_microns [$bbox yMin]]"
}

I get:

$ make RUN_SCRIPT=slack-positions.tcl run
/home/oyvind/OpenROAD-flow-scripts/tools/install/OpenROAD/bin/openroad -exit -no_init -threads 16  -no_splash  slack-positions.tcl
[WARNING STA-0527] unknown path group 'reg2reg'.
resp_msg[15] -0.029667 21.305 36.24
dpath.a_reg.out[7]$_DFFE_PP_/D -0.028715 31.35 18.2
[deleted]
req_rdy 0.194209 0.0 12.88