From 193e7f8a47fb149da250ddfe9ca01e21e4d88571 Mon Sep 17 00:00:00 2001
From: Sebastian Sellmeier <mail@sebastian-sellmeier.de>
Date: Sun, 16 Apr 2023 21:32:52 +0200
Subject: [PATCH] swaylock-fprintd: init at unstable-20230130

---
 .../window-managers/sway/lock-fprintd.nix     | 42 +++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 pkgs/applications/window-managers/sway/lock-fprintd.nix

diff --git a/pkgs/applications/window-managers/sway/lock-fprintd.nix b/pkgs/applications/window-managers/sway/lock-fprintd.nix
new file mode 100644
index 000000000000000..7c668a4f88a700a
--- /dev/null
+++ b/pkgs/applications/window-managers/sway/lock-fprintd.nix
@@ -0,0 +1,42 @@
+{ lib, stdenv, fetchFromGitHub, meson, ninja, pkg-config, scdoc, wayland-scanner
+, wayland, wayland-protocols, libxkbcommon, cairo, gdk-pixbuf, pam
+, dbus, glib, fprintd }:
+
+stdenv.mkDerivation rec {
+  pname = "swaylock-fprintd";
+  version = "unstable-20230130";
+
+  src = fetchFromGitHub {
+    owner = "SL-RU";
+    repo = "swaylock-fprintd";
+    rev = "ffd639a785df0b9f39e9a4d77b7c0d7ba0b8ef79";
+    hash = "sha256-2VklrbolUV00djPt+ngUyU+YMnJLAHhD+CLZD1wH4ww=";
+  };
+
+  postPatch = ''
+    sed -i fingerprint/meson.build \
+      -e 's|/usr/share/dbus-1/interfaces/|'${ fprintd }'/share/dbus-1/interfaces/|'
+  '';
+
+  strictDeps = true;
+  depsBuildBuild = [ pkg-config ];
+  nativeBuildInputs = [ meson ninja pkg-config scdoc wayland-scanner dbus glib ];
+  buildInputs = [ wayland wayland-protocols libxkbcommon cairo gdk-pixbuf pam fprintd ];
+
+  mesonFlags = [
+    "-Dpam=enabled" "-Dgdk-pixbuf=enabled" "-Dman-pages=enabled"
+  ];
+
+  meta = with lib; {
+    description = "Screen locker for Wayland";
+    longDescription = ''
+      swaylock is a screen locking utility for Wayland compositors.
+      Important note: If you don't use the Sway module (programs.sway.enable)
+      you need to set "security.pam.services.swaylock = {};" manually.
+    '';
+    inherit (src.meta) homepage;
+    license = licenses.mit;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ sebtm ];
+  };
+}