build.gradle

// Apply Gradle plugins
plugins {
    id 'java'
    id 'eclipse'
    id 'idea'
    id 'checkstyle'

    id 'net.minecrell.gitpatcher' version '0.9.0'

    id 'net.minecrell.licenser' version '0.4.1'
    id 'com.github.johnrengelman.shadow' version '5.1.0'
}

defaultTasks 'clean', 'licenseFormat', 'build', 'shadowJar'

// Project information
allprojects {
    group = 'blue.lapis.nocturne'
    version = '2.0.0-SNAPSHOT'

    sourceCompatibility = '1.8'
    targetCompatibility = '1.8'
}

patches {
    submodule = 'lib/FernFlower'
    target = file('FernFlower')
    patches = file('patches')
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'idea'
}

project('FernFlower') {
    apply from: rootProject.file('fernflower.gradle')
    compileJava.dependsOn rootProject.tasks.applyPatches
}

// Project repositories
repositories {
    mavenCentral()
}

// Project dependencies
dependencies {
    compile 'org.cadixdev:bombe:0.3.1'
    compile project('FernFlower')

    compile 'com.google.code.findbugs:jsr305:3.0.2'

    testCompile 'junit:junit:4.12'
}

// Read source files using UTF-8
tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'

    options.compilerArgs += [
            '-Xlint:unchecked',
    ]
}

test.testLogging {
    showStandardStreams = true
    exceptionFormat = 'full'
}

processResources {
    from 'LICENSE'
}

jar {
    classifier = 'base'

    manifest {
        attributes(
                'Implementation-Title': project.name,
                'Implementation-Version': version,
                'Main-Class': 'blue.lapis.nocturne.Main'
        )
    }
}

shadowJar {
    classifier = null
    configurations = [project.configurations.compile]
}

// License header formatting
license {
    include '**/*.java'
    include '**/*.css'
    include '**/*.fxml'
}

// check code style
checkstyle {
    toolVersion = '6.12.1'

    configFile = file('etc/checkstyle.xml')
    configProperties = [
            'basedir': project.projectDir,
            'suppressions': project.file('etc/checkstyle-suppressions.xml'),
            'severity': 'warning'
    ]
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allJava
    from tasks.processResources
}

sourceSets {
    test {
        resources {
            srcDir "test"
        }
    }
}

artifacts {
    archives shadowJar
    archives sourcesJar
}

wrapper {
    gradleVersion = '5.2.1'
}