build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.1'
    id 'io.spring.dependency-management' version '1.1.4'
}

group = 'com'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '17'
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-devtools'

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'

    // Databases
    runtimeOnly 'com.mysql:mysql-connector-j'
    implementation 'com.h2database:h2'

    // queryDSL
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    //googleSTT
    implementation(platform("com.google.cloud:libraries-bom:26.1.4"))
    implementation("com.google.cloud:google-cloud-speech")
    implementation("com.google.protobuf:protobuf-java:3.21.12")
    implementation("com.fasterxml.jackson.core:jackson-databind")

    //convertMP3
    implementation 'org.bytedeco:javacv-platform:1.5.5'
    implementation 'org.bytedeco:ffmpeg-platform:4.3.2-1.5.5'

    //apache.lang3
    implementation 'org.apache.commons:commons-lang3:3.12.0'
}


tasks.named('test') {
    useJUnitPlatform()
}

tasks.register('copyGitSubmodule', Copy) {
    from './CONFIG'
    include '*.yml'
    into './src/main/resources'
}

tasks.named('bootBuildImage') {
    environment["BPE_DELIM_JAVA_TOOL_OPTIONS"] = " "
    environment["BPE_APPEND_JAVA_TOOL_OPTIONS"] = "-XX:+ExitOnOutOfMemoryError -XX:MaxDirectMemorySize=10M " +
            "-XX:MaxMetaspaceSize=150M -XX:ReservedCodeCacheSize=60M -Xss256K"

    def dockerhubId = project.property("DOCKERHUB_ID")
    def dockerhubToken = project.property("DOCKERHUB_TOKEN")

    imageName = dockerhubId + "/${project.name}"
    publish = true
    docker {
        publishRegistry {
            username = dockerhubId
            password = dockerhubToken
        }
    }
}

processResources {
    dependsOn copyGitSubmodule
}