build.gradle

plugins {
    id("net.neoforged.moddev") version "2.0.30-beta"
    id("com.matthewprenger.cursegradle") version "1.4.0"
    id("com.diffplug.spotless") version "6.23.3"
    id("com.modrinth.minotaur") version "2.8.7"
}

group = "me.ramidzkh"
version = System.getenv("MOD_VERSION") ?: "0.0.0"

repositories {
    maven {
        name = "Modmaven"
        url = uri("https://modmaven.dev/")

        content {
            includeGroup("appeng")
            includeGroup("blusunrize.immersiveengineering")
            includeGroup("mekanism")
        }
    }

    exclusiveContent {
        forRepository {
            maven {
                name = "Jared maven"
                url = uri("https://maven.blamejared.com")
            }
        }

        filter {
            includeGroup("mezz.jei")
            includeGroup("mezz.jei")
        }
    }

    exclusiveContent {
        forRepository {
            maven {
                name = "CurseForge"
                url = uri("https://www.cursemaven.com")
            }
        }

        filter {
            includeGroup("curse.maven")
        }
    }

    maven {
        url "https://maven.terraformersmc.com"
        content {
            includeGroup "dev.emi"
        }
    }

    mavenLocal()
}

neoForge {
    version = project.neoforge_version
}

dependencies {
    //implementation("blusunrize.immersiveengineering:ImmersiveEngineering:${minecraft_version}-${ie_version}")
    implementation files("deps/ImmersiveEngineering-${minecraft_version}-${ie_version}.jar")

    // We depend on many AE2 internals, such as using their basic cell drive, thus not using classifier = "api"
    implementation("appeng:appliedenergistics2:${ae2_version}")

    runtimeOnly("mekanism:Mekanism:${minecraft_version}-${mekanism_version}:all") {
        exclude(group: "com.blamejared.crafttweaker")
    }

    if (project.runtime_itemlist_mod == "jei") {
        implementation "mezz.jei:jei-${project.minecraft_version}-neoforge:${project.jei_version}"
    } else {
        compileOnly "mezz.jei:jei-${project.minecraft_version}-neoforge:${project.jei_version}"
    }

    if (project.runtime_itemlist_mod == "emi") {
        implementation "dev.emi:emi-neoforge:${project.emi_version}+${project.minecraft_version}"
        // Add JEI so that we can use EMI's builtin compat layer
        runtimeOnly "mezz.jei:jei-${project.minecraft_version}-neoforge:${project.jei_version}"
    } else {
        compileOnly "dev.emi:emi-neoforge:${project.emi_version}+${project.minecraft_version}"
    }

    if (!(project.runtime_itemlist_mod in ["jei", "emi"])) {
        throw new GradleException("Invalid runtime_itemlist_mod value: " + project.runtime_itemlist_mod)
    }

    compileOnly("curse.maven:jade-324717:${jade_id}")
}

sourceSets {
    main {
        resources {
            srcDir("src/generated/resources")
        }
    }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

////////////////////
// Minecraft
neoForge {
    mods {
        immeng {
            sourceSet sourceSets.main
        }
    }

    runs {
        configureEach {
            systemProperty("forge.logging.console.level", "debug")
        }

        client {
            client()
        }

        server {
            server()
            programArgument '--nogui'
        }

        data {
            data()
            programArguments.addAll "--mod", "immeng", "--all", "--output", file("src/generated/resources/").getAbsolutePath(), "--existing", file("src/main/resources/").getAbsolutePath()
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
// When "copyIdeResources" is enabled, this will also run before the game launches in IDE environments.
// See https://docs.gradle.org/current/dsl/org.gradle.language.jvm.tasks.ProcessResources.html
tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            version: version,
            loader_version_range: loader_version_range,
            neo_version_range: neo_version_range,
            ae2_version_range: ae2_version_range,
            ie_version_range: ie_version_range,
    ]
    inputs.properties(replaceProperties)

    filesMatching(["META-INF/neoforge.mods.toml"]) {
        expand replaceProperties
    }
}

/////////////
// Spotless
spotless {
    java {
        target("src/main/java/**/*.java")

        endWithNewline()
        indentWithSpaces()
        removeUnusedImports()
        toggleOffOn()
        eclipse().configFile("codeformat/codeformat.xml")
        importOrderFile("codeformat/ae2.importorder")
    }

    format("json") {
        target("src/*/resources/**/*.json")
        targetExclude("src/generated/resources/**")
        prettier().config(parser: "json")
    }
}

////////////////
// CurseForge
System.getenv("CURSEFORGE")?.with { String key ->
    curseforge {
        apiKey = key

        project {
            id = "992377"
            changelogType = "markdown"
            changelog = "View changelog at [the release page](https://github.com/AppliedEnergistics/Immersive-Energistics/releases/tag/${version})"

            if (version.contains("alpha")) {
                releaseType = "alpha"
            } else if (version.contains("beta")) {
                releaseType = "beta"
            } else {
                releaseType = "release"
            }

            addGameVersion("${minecraft_version}")
            addGameVersion("NeoForge")

            mainArtifact(jar) {
                displayName = "${project.version}"

                relations {
                    requiredDependency("applied-energistics-2")
                    requiredDependency("immersive-engineering")
                }
            }
        }
    }
}

////////////////
// Modrinth
modrinth {
    token.set(System.getenv("MODRINTH"))
    projectId.set("immersive-energistics")
    changelog.set("View changelog at [the release page](https://github.com/AppliedEnergistics/Immersive-Energistics/releases/tag/${version})")
    versionNumber.set(project.version)

    if (version.contains("alpha")) {
        versionType.set("alpha")
    } else if (version.contains("beta")) {
        versionType.set("beta")
    } else {
        versionType.set("release")
    }

    uploadFile.set(jar)
    gameVersions.add(minecraft_version)
    loaders.add("neoforge")

    dependencies {
        required.project("ae2")
        required.project("immersiveengineering")
    }
}

tasks.modrinth.onlyIf {
    System.getenv("MODRINTH")
}